hm_read_mat64.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat64            ../starter/source/materials/mat/mat064/hm_read_mat64.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.f90
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.f
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.f
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat64(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS  ,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT   , 
     .                         UNITAB ,MAT_ID   ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,IPM      ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW64 WITH HM READER 
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB
      my_real, INTENT(INOUT)                :: PM(NPROPM),PARMAT(100),UPARAM(MAXUPARAM)
      INTEGER, INTENT(INOUT)                :: IPM(NPROPMI),ISRATE,IFUNC(MAXFUNC),NFUNC,MAXFUNC,MAXUPARAM,NUPARAM, NUVAR,IMATVIS
      TYPE(mlaw_tag_),INTENT(INOUT)         :: MTAG
      INTEGER,INTENT(IN)                    :: MAT_ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)       :: TITR
      TYPE(submodel_data),INTENT(IN)        :: LSUBMODEL(NSUBMOD)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real 
     .    e,nu,cp,vmc,d,n,md,
     .    c1, g,temp,v0,c2,yfac(2),fac_l,fac_t,fac_m,fac_c
      INTEGER I,J
      my_real :: RHO0, RHOR, YFAC_UNIT
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------      
      is_encrypted = .false.
      is_available = .false.
      israte = 0
      imatvis = 0
      nuparam = 15
      nuvar = 7
      nfunc=2
      mtag%G_PLA  = 1
      mtag%L_PLA  = 1
 
      CALL hm_option_is_encrypted(is_encrypted)
      !line+1
      CALL hm_get_floatv('MAT_RHO'        ,rho0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho'      ,rhor     ,is_available, lsubmodel, unitab)
      !line-2
      CALL hm_get_floatv('MAT_E'          ,e        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_NU'         ,nu       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('CP'             ,cp       ,is_available, lsubmodel, unitab)
      !line-3
      CALL hm_get_floatv('MAT_D'          ,d        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_N'          ,n        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('M64_Md'         ,md       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('M64_Vo'         ,v0       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('M64_Vm'         ,vmc      ,is_available, lsubmodel, unitab)
      !line-4      
      CALL hm_get_intv  ('M64_FUNCT_ID_0' ,ifunc(1) ,is_available, lsubmodel)
      CALL hm_get_intv  ('M64_FUNCT_ID_1' ,ifunc(2) ,is_available, lsubmodel)    
      CALL hm_get_floatv('M64_SCALE_0'    ,yfac(1)  ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('M64_SCALE_1'    ,yfac(2)  ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('M64_INI_TEMP'   ,temp     ,is_available, lsubmodel, unitab)
      !CALL HM_GET_FLOATV(''       ,HL       ,IS_AVAILABLE, LSUBMODEL, UNITAB)   no longer read
      !units
      CALL hm_get_floatv_dim('M64_SCALE_0'    ,yfac_unit  ,is_available, lsubmodel, unitab)
      
      !---DEFAULT VALUES---! 
      IF(rhor == zero)rhor=rho0
      pm(1) =rhor
      pm(89)=rho0
      IF(v0 == zero.OR.v0 >= one)v0=em20
      IF(cp == zero)THEN
       cp = zero
      ELSE
       cp = one/cp
      ENDIF
      IF(yfac(1) == zero) yfac(1)= one*yfac_unit
      IF(yfac(2) == zero) yfac(2)= one*yfac_unit
      IF(vmc == zero.OR.vmc > one) vmc = one
 
      !---STORAGE---!
      g = half*e/(one + nu)
      c1=e/three/(one - two*nu)
      uparam(1)  = e
      uparam(2)  = e/(one - nu*nu)
      uparam(3)  = nu*uparam(2)
      uparam(4)  = g
      uparam(5)  = nu
      uparam(6)  = d
      uparam(7)  = n
      uparam(8)  = md
      uparam(9)  = v0
      uparam(10) = vmc
      uparam(11) = cp
      uparam(12) = temp
      uparam(13) = yfac(1)
      uparam(14) = yfac(2)      
      uparam(15) = zero !HL
 
      parmat(1) = c1
      parmat(2) = e
      parmat(3) = nu 
      !Formulation for solid elements time step computation.
      parmat(16) = 2
      parmat(17) =  (one - two*nu)/(one - nu) ! == TWO*G/(C1+FOUR_OVER_3*G)
 
      ! Properties compatibility       
      CALL init_mat_keyword(matparam,"SHELL_ISOTROPIC") 
 
       !---LISTING OUTPUT---!      
      WRITE(iout,1001) trim(titr),mat_id,64
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1002) rho0
        WRITE(iout,1100)e,nu,cp,n,d,v0,md,vmc,temp
        WRITE(iout,1200)(ifunc(j),yfac(j),j=1,2) 
      ENDIF
 
      RETURN
 1000 FORMAT(/
     . 5x,40h  trip-steels  plastic law              ,/,
     & 5x,40h  ------------------------              ,/)
 1001 FORMAT(
     & 5x,a,/,
     & 5x,'material number . . . . . . . . . . . . =',I10/,
     & 5X,'material law. . . . . . . . . . . . . . =',I10/)
 1002 FORMAT(
     & 5X,'initial density . . . . . . . . . . . . =',1PG20.13/)
 1100 FORMAT(
     & 5X,'young''s modulus. . . . . . . . . . . . . . .  =',E12.4/
     & 5X,'poisson''s ratio. . . . . . . . . . . . . . .  =',E12.4/
     & 5X,'heat capacitivity  . . .. . . . . . . . . . . =',E12.4/
C     & 5X,'HEAT LATENT OF PHASE CHANGE . . . . . . . . . =',E12.4/
     & 5X,'material parameter(n)      . . . . . . . . .=',E12.4/
     & 5X,'material parameter(d)     . . . . .. . . . .=',E12.4/
     & 5X,'material parameter(v0)     . . . . .. . . . =',E12.4/
     & 5X,'limit marteniste temperature(md) . . . . . . =',E12.4/
     & 5X,'content martensite volume fraction(vmc) . . . =',E12.4/
     & 5X,'initial temperature . .  . . . . . . . . . .  =',E12.4)
 1200 FORMAT(
     & 5X,'yield stress FUNCTION number. . . . . . . . . =',I8/
     & 5X,'yield scale factor. . . . . . . . . . . . . . =',E12.4)
 
 
      END SUBROUTINE