hm_read_mat75.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat75            ../starter/source/materials/mat/mat075/hm_read_mat75.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat75(UPARAM , MAXUPARAM, NUPARAM,
     .                         NUVAR  , IFUNC,     MAXFUNC, NFUNC, PARMAT,
     .                         UNITAB , MAT_ID,    TITR,    MTAG,  LSUBMODEL,
     .                         PM     , MATPARAM)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW75 WITH HM READER 
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE matparam_def_mod    
      USE elbuftag_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, INTENT(INOUT)                :: PARMAT(100), UPARAM(MAXUPARAM), PM(NPROPM)
      INTEGER, INTENT(INOUT)                :: IFUNC(MAXFUNC), NFUNC, MAXFUNC, MAXUPARAM, 
     .     nuparam, nuvar
      INTEGER, INTENT(IN)                    :: MAT_ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN)       :: TITR
      TYPE(SUBMODEL_DATA),INTENT(IN)        :: LSUBMODEL(*)
      TYPE(mlaw_tag_), INTENT(INOUT)   :: MTAG
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER MATS,IFLAG1,IFLAG2,ITEMAX
      my_real
     .        CE, PE, PS, NN, TOL, YOUNG, NU, BULK, RHO0, RHOR
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE
C-----------------------------------------------
C     S o u r c e 
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      CALL hm_option_is_encrypted(is_encrypted)
C----------------------------------------------------------------
C     #RhoO rho_ref
      CALL hm_get_floatv('MAT_RHO'    ,rho0        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho'  ,rhor        ,is_available, lsubmodel, unitab)
C----------------------------------------------------------------
      CALL hm_get_floatv('MAT_E', young, is_available, lsubmodel, unitab)
      CALL hm_get_floatv('mat_nu', NU, IS_AVAILABLE, LSUBMODEL, UNITAB)
 
      CALL HM_GET_INTV('mat1', MATS, IS_AVAILABLE, LSUBMODEL)
      CALL HM_GET_INTV('hflag1', IFLAG1, IS_AVAILABLE, LSUBMODEL)
      CALL HM_GET_INTV('hflag2', IFLAG2, IS_AVAILABLE, LSUBMODEL)
      CALL HM_GET_INTV('nppmax', ITEMAX, IS_AVAILABLE, LSUBMODEL)
 
      CALL HM_GET_FLOATV('mat_ppres', PE, IS_AVAILABLE, LSUBMODEL, UNITAB)
      CALL HM_GET_FLOATV('mat_ypres', ps, is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_EXP1', nn, is_available, lsubmodel, unitab)
 
      CALL hm_get_floatv('MAT_Tol', tol, is_available, lsubmodel, unitab)
C     
      IF(iflag1 <= 0) iflag1=1
      IF(iflag2 <= 0) iflag2=1
      IF(itemax <= 0) itemax=5
      IF(nn  <= zero) nn=two
      IF(tol <= zero) tol=em08    
 
      nuvar = 4
      pm(1) = rhor
      pm(89) = rho0
      bulk=young/three/(one-two*nu)
      ce=sqrt(bulk/rho0)
C     
      uparam(1) = bulk
      uparam(2) = pe
      uparam(3) = ps
      uparam(4) = nn
      uparam(5) = tol
      uparam(6) = mats
      uparam(7) = iflag1
      uparam(8) = iflag2
      uparam(9) = young/(one+nu)
      uparam(10)= half*uparam(9)
      uparam(17)= itemax
C     
      nuparam= 17
C     
      parmat(1) = bulk
      parmat(2) = young
      parmat(3) = nu
C     Formulation for solid elements time step computation.
      parmat(16) = 2
      parmat(17) = (one - two*nu)/(one - nu) ! ==TWO*G/(BULK+sFOUR_OVER_3*G)
C
      ! MATPARAM keywords
      CALL init_mat_keyword(matparam,"HOOK")
C
      ! Properties compatibility  
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")  
      CALL init_mat_keyword(matparam,"SPH")       
C 
C----------------------
      WRITE(iout, 900) trim(titr),mat_id,75
      WRITE(iout,1000)
      IF (is_encrypted) THEN
         WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
         WRITE(iout,950)rho0
         WRITE(iout,1100) young, nu, uparam(10), bulk
         WRITE(iout,1200) mats, iflag1, iflag2, itemax, pe, ps, nn
         WRITE(iout,1300) tol, ce
      ENDIF
C--------
C     ERRORS
C--------
      IF (pe > ps) THEN
         CALL ancmsg(msgid=897,
     .        msgtype=msgerror,
     .        anmode=aninfo,
     .        i1=mat_id,
     .        c1=titr)
      ENDIF
C     
      RETURN
C     
  900 FORMAT(/
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER. . . . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW . . . . . . . . . . . . . . . .=',i10/)
 950  FORMAT(
     &     5x,'INITIAL DENSITY    . . . . . . . . . . .=',1pg20.13/)
 1000 FORMAT(
     &     5x,'  POROUS MATERIAL',/,
     &     5x,'  ---------------',//)
 1100 FORMAT(
     &     5x,'YOUNG',1h','s modulus . . . . . . . . . . . . =',1PG20.13/,
     &5X,'poisson',1H','S RATIO . . . . . . . . . . . . =',1pg20.13/,
     &     5x,'SHEAR MODULUS . . . . . . . . . . . . . =',1pg20.13/,
     &     5x,'BULK  MODULUS . . . . . . . . . . . . . =',1pg20.13//)
 1200 FORMAT(
     &     5x,'SOLID MATERIAL IDENTIFIER . . . . . . . =',i10/
     &     5x,'PRESSURE FORMULATION FLAG . . . . . . . =',i10/
     &     5x,'DEVIATORIC STRESSES FORMULATION FLAG. . =',i10/
     &     5x,'MAXIMUM NUMBER OF ITERATIONS. . . . . . =',i10//
     &     5x,'ELASTIC COMPACTION PRESSURE (PE). . . . =',1pg20.13/
     &     5x,'SOLID COMPACTION PRESSURE (PS). . . . . =',1pg20.13/
     &     5x,'EXPONENT (NN) . . . . . . . . . . . . . =',1pg20.13)
 1300 FORMAT(
     &     5x,'CONVERGENCE TOLERANCE (TOL) . . . . . . =',1pg20.13/
     &     5x,'INITIAL POROUS BULK SOUND SPEED . . . . =',1pg20.13)
      END