hm_read_mat90.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat90                  ../starter/source/materials/mat/mat090/hm_read_mat90.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat                    ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                         ../starter/source/output/message/message.F
!||    hm_get_float_array_index       ../starter/source/devtools/hm_reader/hm_get_float_array_index.F
!||    hm_get_float_array_index_dim   ../starter/source/devtools/hm_reader/hm_get_float_array_index_dim.F
!||    hm_get_floatv                  ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_int_array_index         ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv                    ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted         ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword               ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod                   ../starter/share/modules1/elbuftag_mod.F
!||    message_mod                    ../starter/share/message_module/message_mod.F
!||    submodel_mod                   ../starter/share/modules1/submodel_mod.F
!||    table_mod                      ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat90(UPARAM  ,MAXUPARAM,NUPARAM ,NUVAR    ,IFUNC    ,
     .                         MAXFUNC ,NFUNC    ,PARMAT  ,UNITAB   ,ID       ,
     .                         TITR    ,ISRATE   ,PM      ,IMATVIS  ,LSUBMODEL,
     .                         MTAG    ,MATPARAM ,NVARTMP )
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   READ MAT LAW90 WITH HM READER
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE    
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE table_mod
      USE submodel_mod
      USE matparam_def_mod
      USE elbuftag_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (unit_type_),INTENT(IN) ::unitab 
      my_real, INTENT(INOUT)          :: parmat(100),uparam(maxuparam),pm(npropm)
      INTEGER, INTENT(INOUT)          :: IFUNC(MAXFUNC),NFUNC,MAXFUNC,MAXUPARAM,NUPARAM, NUVAR,ISRATE,IMATVIS
      INTEGER, INTENT(INOUT)          :: NVARTMP
      INTEGER, INTENT(IN)             :: ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(*)
      TYPE(mlaw_tag_),INTENT(INOUT)         :: MTAG
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IFLAG,IDAM ,ISMOOTH ,TFLAG,FAIL 
      my_real E0,NU,FCUT,G,C1,SHAPE,HYS,ALPHA
      my_real RATE(1000),YFAC(1000),YFAC_DIM(1000)
      my_real :: rho0, rhor,fcut_unit,econt,tcut
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------      
      is_encrypted = .false.
      is_available = .false.
      idam = 0
      israte = 0
      imatvis = 2
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_RHO'   ,rho0    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho' ,rhor    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_E0'    ,e0      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_NU'    ,nu      ,is_available, lsubmodel, unitab)
      CALL hm_get_intv  ('NL'        ,nfunc   ,is_available, lsubmodel)
      CALL hm_get_intv  ('Ismooth'   ,ismooth ,is_available, lsubmodel)
      CALL hm_get_floatv('Fcut'      ,fcut    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_SHAPE' ,shape   ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Hys'       ,hys     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_ALPHA' ,alpha   ,is_available, lsubmodel, unitab)
      CALL hm_get_intv  ('MAT_TFLAG' ,tflag   ,is_available, lsubmodel)
      CALL hm_get_intv  ('LSD_MAT83_FAIL'  ,fail   ,is_available, lsubmodel)
      CALL hm_get_floatv('LSD_MAT83_ED' ,econt    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('LSD_MAT83_TC' ,tcut ,is_available, lsubmodel, unitab)
!   IDAM  ---> not documented, not included within LAW90.cfg
!!      CALL HM_GET_INTV  ('IDAM'      ,IDAM    ,IS_AVAILABLE, LSUBMODEL)
!
      IF (nfunc == 0) THEN
          CALL ancmsg(msgid=866,
     .                msgtype=msgerror,
     .                anmode=aninfo_blind,
     .                i1=id,
     .                c1=titr)
      ENDIF 
      IF(tflag == 0) tflag = 1
      IF(econt == zero) econt = e0
      IF(tcut == zero) tcut = ep20
!
!... fonction de charge      
!
      DO i=1,nfunc
        CALL hm_get_int_array_index      ('fct_IDL'     ,ifunc(i)    ,i ,is_available, lsubmodel)
        CALL hm_get_float_array_index    ('EpsilondotL' ,rate(i)     ,i ,is_available, lsubmodel, unitab)
        CALL hm_get_float_array_index    ('FscaleL'     ,yfac(i)     ,i ,is_available, lsubmodel, unitab)        
        CALL hm_get_float_array_index_dim('FscaleL'     ,yfac_dim(i) ,i ,is_available, lsubmodel, unitab)
      ENDDO
!
      DO i=1,nfunc
        IF (ifunc(i) == 0) THEN
          CALL ancmsg(msgid=126,
     .                msgtype=msgerror,
     .                anmode=aninfo_blind_1,
     .                i1=id,
     .                c1=titr,
     .                i2=ifunc(i))
        ENDIF
        IF(yfac(i) == zero) yfac(i) = yfac_dim(i) * one
      ENDDO
      hys = abs(hys)
      iflag = 0
      IF (nfunc > 0  .AND. hys == zero) iflag = 1     
      IF (nfunc > 0  .AND. hys > zero)  iflag  = 2    ! unloading is quasi-static
      IF (shape == zero) shape = one
      IF (alpha == zero) alpha = one
      IF (hys  == zero) hys = one
      IF (rhor==zero) rhor=rho0
      IF (fcut == zero .AND. nfunc > 1 ) THEN
        fcut = ep03*unitab%FAC_T_WORK
        ismooth = 1  
      ENDIF
      IF(ismooth == 0 .AND. fcut > zero .AND. nfunc > 1) ismooth = 1
      IF(nfunc == 1) ismooth = 0
      pm(1) = rhor
      pm(89)= rho0
        
      g = half*e0/(one + nu)
      uparam(1) = e0
      uparam(4) = g
      uparam(5) = nu 
      uparam(6) = shape
      uparam(7) = hys
      uparam(9) = iflag
      uparam(10) = idam 
      DO i=1,nfunc
         uparam(i + 10)        =  rate(i)
         uparam(i + 10 + nfunc) = yfac(i)
      END DO
      nuparam =13 + 2*nfunc  
      uparam(nuparam) = alpha
      nuparam = nuparam + 1
      uparam(nuparam) = tflag 
      nuparam = nuparam + 1
      uparam(nuparam ) = fail
      nuparam = nuparam + 1
      uparam(nuparam ) = tcut
      nuparam = nuparam + 1
      uparam(nuparam ) = econt
!   
      c1=econt /three/(one - two*nu)
      parmat(1) = c1
      parmat(2) = econt
      parmat(3) = nu
      parmat(4) = ismooth
      parmat(5) = fcut
 
      israte = ismooth 
      nuvar   = 10
      nvartmp = nfunc*3
        ! MTAG variable activation   
      mtag%G_EPSD = 1
      mtag%L_EPSD = 1
C
      WRITE(iout,1000)
      WRITE(iout,1001) trim(titr),id,90
      IF (is_encrypted) THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1100)rho0                                                     
        WRITE(iout,1150)e0,nu, tflag, econt, tcut,fail
        WRITE(iout,1200)fcut,ismooth,shape,hys,alpha
        WRITE(iout,1300)(ifunc(j),rate(j),yfac(j),j=1,nfunc )
      ENDIF
c-----------------
      CALL init_mat_keyword(matparam,"TOTAL")
      IF (nu >= 0.49) THEN
        CALL init_mat_keyword(matparam,"INCOMPRESSIBLE")
      ELSE
        CALL init_mat_keyword(matparam,"COMPRESSIBLE")
      END IF
      CALL init_mat_keyword(matparam,"HOOK")
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")
c-----------------
      RETURN
!---
 1000 FORMAT(
     & 5x,40h  tabulated non linear visco elastic law,/,
     & 5x,40h  --------------------------------------,//)
 1001 FORMAT(/
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . .=',i10/)
 1100 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . .=',1pg20.13/)
 1150 FORMAT(
     & 5x,'INITIAL YOUNG''S MODULUS. . . . . . . .=',1pg20.13/,
     & 5x,'POISSON''S RATIO. . . . . . . . . . . .=',1pg20.13/,
     & 5x,'TENSILE STRESS FLAG . . . . . . . . . =',i10/,
     & 10x, '1 : FOLLOW THE INPUT CURVE ' /,
     & 10x, '2 : FOLLOW E0 '/                            
     & 5x,'OPTIONAL YOUNG MODULUS . . . . . . . . =',1pg20.13/,
     & 5x,'TENSION CUT-OOF STRESS . . . . . . . . =',1pg20.13/,
     & 5x,'FAILURE OPTION AFTER CUT-OFF STRESS IS REACHED =',i10/,
     & 10x, '0 : TENSILE STRESS REMAINS AT CUT-OFF VALUE'/,
     & 10x, '1 : THE ELEMENT IS DELETED '/)
 
 1200 FORMAT(
     & 5x,'STRAIN RATE COEFFICIENT . . . . . . . .=',1pg20.13/,
     & 5x,'FLAG FOR FILTERING STRAIN RATE  . . . .=',i10/,
     & 5x,'SHAPE FACTOR FOR UNLOADING  . . . . . .=',1pg20.13/,
     & 5x,'HYSTERETIC UNLOADING FACTOR . . . . . .=',1pg20.13/,
     & 5x,'EXPONANT FACTOR FOR UNLOADING . . . . .=',1pg20.13/)
 1300 FORMAT(
     & 5x,'LOADING STRESS FUNCTION NUMBER  . . . .=',i10/,
     & 5x,'STRAIN RATE . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'SCALE FACTOR. . . . . . . . . . . . . .=',1pg20.13/)
 1500 FORMAT(
     & 5x,'PRESSURE DEPENDENT YIELD FUNCTION . . .=',i10/
     & 5x,'PRESSURE SCALE FACTOR . . . . . . . . .=',1pg20.13)
      END