hm_read_mat92.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat92            ../starter/source/materials/mat/mat092/hm_read_mat92.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim        ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat92(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS  ,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT   , 
     .                         UNITAB ,MAT_ID   ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,IPM      ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW92 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, INTENT(INOUT)                :: PM(NPROPM),PARMAT(100),UPARAM(MAXUPARAM)
      INTEGER, INTENT(INOUT)                :: IPM(NPROPMI),ISRATE,IFUNC(MAXFUNC),NFUNC,MAXFUNC,MAXUPARAM,NUPARAM, NUVAR,IMATVIS
      TYPE(mlaw_tag_),INTENT(INOUT)         :: MTAG
      INTEGER,INTENT(IN)                    :: MAT_ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR
      TYPE(SUBMODEL_DATA),INTENT(IN)        :: LSUBMODEL(*)
      TYPE(MATPARAM_STRUCT_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER ID,ITEST,IDAM
      my_real
     .  E,NU,G,MU,LAM,D,RBULK,SCALEFAC,C(5),
     .  a1,a2,a3,a4,nu0 ,fac_unit  
      CHARACTER(LEN=NCHARFIELD) ::  STRING
      my_real :: RHO0, RHOR
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------      
      is_encrypted = .false.
      is_available = .false.
      idam = 0
      israte = 0
      imatvis = 1
      nuvar = 0
 
      CALL hm_option_is_encrypted(is_encrypted)
      !line+1
      CALL hm_get_floatv('MAT_RHO'      ,rho0     ,is_available, lsubmodel, unitab)
      !line-2
      CALL hm_get_floatv('MAT_MUE1'     ,mu       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_D'        ,d        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_Lamda'    ,lam      ,is_available, lsubmodel, unitab)
      !line-3
      CALL hm_get_intv  ('Itype'        ,itest    ,is_available, lsubmodel)
      CALL hm_get_intv  ('MAT_FCT_IDI'  ,ifunc(1) ,is_available, lsubmodel)
      CALL hm_get_floatv('MAT_NU'       ,nu       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_FScale'   ,scalefac ,is_available, lsubmodel, unitab)
      IF(scalefac == zero)THEN 
        CALL hm_get_floatv_dim('MAT_FScale' ,fac_unit    ,is_available, lsubmodel, unitab)
        scalefac = one * fac_unit
      ENDIF       
 
      !========== DEFAULT VALUES=============!              
      rhor=zero
      !IF(RHOR==ZERO)RHOR=RHO0
      pm(1) =rhor
      pm(89)=rho0
 
      !C By default we consider the uniaxial test 
      IF(itest == 0) itest = 1
      !C Uniaxial - itest = 1       
      !C equibiaxial - Itest = 2
      !c Planar - Itest = 3
      !C       
      !the proposed one      READ(LINE,FMT=FMT_A_I_F)STRING,IFUNC(1),NU     
      !CSTRING = UNIAXIAL
      !CSTRING = EQUIBIAXIAL 
      !CSTRING = PLANAR 
      !C By default we consider the unniaxial test  
      !!the proposed one       ITEST = 1  
      !!the proposed one       IF(STRING(1:8) == ' ' ) THEN
      !!the proposed one          ITEST = 1
      !!the proposed one       ELSEIF(STRING(1:10) == 'EQUIBIAXIA') THEN
      !!the proposed one          ITEST = 2
      !!the proposed one       ELSEIF(STRING(1:6) == 'PLANAR') THEN
      !!the proposed one         ITEST = 3
      !!the proposed one       ENDIF
      c(1) = half
      c(2) = one/twenty
      c(3) = eleven/1050.d00
      c(4) = 19.d00/7000.d00
      c(5) = 519.d00/673750.d00
C
      IF(lam == zero) lam = seven  
      a1 = one/lam**2
      a2 = a1**2
      a3 = a1*a2
      a4 = a2**2
      g= mu*(one +  three*a1/five + eighty19*a2/175.d00 
     .         + 513.d00*a3/875.d00 + 42039.d00*a4/67375.d00) 
        
      nfunc= 0
      rbulk = zero
      IF(ifunc(1) /= 0) THEN
       nfunc = 1
       IF (nu == zero) nu= 0.495
      ELSEIF(d == zero) THEN
        nu = 0.495
        rbulk = two_third*(one + nu)*g/(one - two*nu)
        d  = two/rbulk 
      ELSE
        rbulk =  two/d 
      ENDIF
!
! computing E
!
      e = nine*rbulk*g/max(em20,(three*rbulk + g))  
      IF(ifunc(1) == 0 ) nu = (three*rbulk -two*g)/(three*rbulk + g)/two
C     
      uparam(1) = mu
      uparam(2) = d
      uparam(3) = lam
      uparam(4) = g
      uparam(5) = rbulk
      uparam(6) = c(1)
      uparam(7) = c(2)
      uparam(8) = c(3)
      uparam(9) = c(4)
      uparam(10) = c(5) 
      uparam(11) = nu  
      uparam(12) = itest
      uparam(14) = scalefac
     
      nuparam = 14
      IF(nuparam > maxuparam)THEN
        WRITE(iout,*)' ** ERROR : NUPARAM GT MAXUPARAM'
        WRITE(iout,*)'      NUPARAM =',nuparam,
     .                ' MAXUPARAM =',maxuparam
      ENDIF
!
      parmat(1) = rbulk
      parmat(2) = e
      parmat(3) = nu
      
       mtag%L_EPSA  = 1 ! hyperelastic energy needed for mullins
       imatvis = 1                 
       pm(100) = rbulk
c-----------------
      CALL init_mat_keyword(matparam,"INCOMPRESSIBLE")
      CALL init_mat_keyword(matparam,"TOTAL")
      CALL init_mat_keyword(matparam,"HOOK")
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SOLID_ISOTROPIC")
c-----------------
      !========== OUTPUT =============!
      WRITE(iout,1001) trim(titr),mat_id,92
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE 
        WRITE(iout,1002) rho0
        IF(ifunc(1) > 0) THEN
           IF(itest == 1) THEN 
              WRITE(iout,1200)ifunc(1),scalefac, nu
           ELSEIF(itest == 2) THEN 
              WRITE(iout,1300)ifunc(1),scalefac, nu
           ELSEIF(itest == 3) THEN 
              WRITE(iout,1400)ifunc(1),scalefac, nu
           ENDIF   
        ELSE
          WRITE(iout,1100)mu,d,lam, nu
        ENDIF  
      ENDIF
 
C-----------------------------------------------
 1000 FORMAT(
     & 5x,'  ARRUDA-BOYCE  LAW ',/,
     & 5x,'  ---------------- ',/)
 1001 FORMAT(
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . =',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . . =',i10/)
 1002 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . . =',1pg20.13/)
 1100 FORMAT(
     & 5x,'MU . . . . . . . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'D. . . . . . . . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'LAM. . . . . . . . . . . . . . . . . . .=',1pg20.13/
     & 5x,'POISSON RATIO. . . . . . . . . . . . . .=',e12.4//) 
 1200 FORMAT(
     & 5x,'UNIAXIAL DATA TEST CURVE  .  . . . . . .=',i10/
     & 5x,'SCALE FACTOR FOR STRESS IN FUNCTION. . .=',1pg20.13/
     & 5x,'POISSON RATIO. . . . . . . . . . . . . .=',e12.4///) 
 1300 FORMAT(
     & 5x,'EQUIBIAXIAL DATA TEST CURVE. . . . . . .=',i10/
     & 5x,'SCALE FACTOR FOR STRESS IN FUNCTION. . .=',1pg20.13/
     & 5x,'POISSON RATIO. . . . . . . . . . . . . .=',e12.4///)
 1400 FORMAT(
     & 5x,'PLANAR DATA TEST CURVE  . .  . . . . . .=',i10/
     & 5x,'SCALE FACTOR FOR STRESS IN FUNCTION. . .=',1pg20.13/
     & 5x,'POISSON RATIO. . . . . . . . . . . . . .=',e12.4///)
C-----------------------------------------------
 
 
      RETURN
      END