hm_read_nonlocal.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_nonlocal       ../starter/source/materials/nonlocal/hm_read_nonlocal.F
!||--- called by ------------------------------------------------------
!||    read_material_models   ../starter/source/materials/read_material_models.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    fretitl2               ../starter/source/starter/freform.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_count        ../starter/source/devtools/hm_reader/hm_option_count.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod           ../starter/share/modules1/elbuftag_mod.F
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_nonlocal(MAT_PARAM ,NLOC_DMG ,MLAW_TAG ,IPM    ,
     .                            UNITAB    ,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE nlocal_reg_mod
      USE elbuftag_mod            
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C============================================================================
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(nlocal_str_)                                 :: NLOC_DMG
      TYPE(mlaw_tag_), DIMENSION(NUMMAT), INTENT(INOUT) :: MLAW_TAG
      INTEGER ,DIMENSION(NPROPMI,NUMMAT), INTENT(INOUT) :: IPM
      TYPE (UNIT_TYPE_) ,INTENT(IN)                     :: UNITAB 
      TYPE (SUBMODEL_DATA)    ,DIMENSION(*)      ,INTENT(IN)    :: LSUBMODEL
      TYPE (MATPARAM_STRUCT_) ,DIMENSION(NUMMAT) ,INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: INL,FLAGMAT,FLAGUNIT,IUNIT,UID,MAT_ID,IMAT,ILAW,NNLOC
      my_real :: rlen,le_max
      CHARACTER(LEN=NCHARTITLE)::TITR
      LOGICAL IS_AVAILABLE
C=======================================================================
      is_available = .false.
c--------------------------------------------------
c     COUNT NONLOCAL MODELS USING CFG FILES
c--------------------------------------------------
c      
      CALL hm_option_count('/NONLOCAL',nnloc)
      ! Allocation for non-local computation
      IF ((nnloc > 0).OR.(nloc_dmg%IMOD>0)) THEN 
        nloc_dmg%IMOD = 1
        IF (.NOT.ALLOCATED(nloc_dmg%LEN))    ALLOCATE(nloc_dmg%LEN(nummat))
        IF (.NOT.ALLOCATED(nloc_dmg%LE_MAX)) ALLOCATE(nloc_dmg%LE_MAX(nummat))
        IF (.NOT.ALLOCATED(nloc_dmg%DENS))   ALLOCATE(nloc_dmg%DENS(nummat))
        IF (.NOT.ALLOCATED(nloc_dmg%DAMP))   ALLOCATE(nloc_dmg%DAMP(nummat))
        IF (.NOT.ALLOCATED(nloc_dmg%SSPNL))  ALLOCATE(nloc_dmg%SSPNL(nummat))
        nloc_dmg%LEN(1:nummat)    = zero
        nloc_dmg%LE_MAX(1:nummat) = zero
        nloc_dmg%DENS(1:nummat)   = zero
        nloc_dmg%DAMP(1:nummat)   = zero
        nloc_dmg%SSPNL(1:nummat)  = zero
      ENDIF
c
c--------------------------------------------------
c     START BROWSING NONLOCAL MODELS
c--------------------------------------------------
c
      CALL hm_option_start('/NONLOCAL')
c
c--------------------------------------------------
      DO inl = 1,nnloc
c
        CALL hm_option_read_key(lsubmodel,
     .                          option_id = mat_id ,
     .                          unit_id   = uid    )
c--------------------------------------------------
c       Check MAT_ID
c--------------------------------------------------
        flagmat  = 0
        ! Loop over materials
        DO imat=1,nummat-1
          ! If found
          IF (mat_id == ipm(1,imat)) THEN
            flagmat = 1
            CALL fretitl2(titr,ipm(npropmi-ltitr+1,imat),ltitr)
            EXIT
          ENDIF
        ENDDO
        IF (mat_id > 0 .AND. flagmat == 0) THEN
          CALL ancmsg(msgid=1663,anmode=aninfo,msgtype=msgerror,
     .                i1= mat_id, c1='NONLOCAL', c2='NONLOCAL', c3='')
          cycle                           
        ENDIF
c--------------------------------------------------
c       Check UNIT_ID
c--------------------------------------------------
        flagunit = 0
        DO iunit=1,unitab%NUNITS
          IF (unitab%UNIT_ID(iunit) == uid) THEN
            flagunit = 1
            EXIT
          ENDIF
        ENDDO
        IF (uid > 0 .AND. flagunit == 0) THEN
          CALL ancmsg(msgid=659, anmode=aninfo, msgtype=msgerror,
     .                i1= mat_id,
     .                i2= uid,
     .                c1='NONLOCAL',
     .                c2='NONLOCAL',
     .                c3= '')                             
        ENDIF
c--------------------------------------------------
c       Read card
c--------------------------------------------------
        CALL hm_get_floatv('LENGTH' ,rlen    ,is_available, lsubmodel, unitab)
        CALL hm_get_floatv('LE_MAX' ,le_max  ,is_available, lsubmodel, unitab)
c--------------------------------------------------
c       Check value
c--------------------------------------------------
        IF (le_max > zero) THEN 
          ! Save maximal target element length
          nloc_dmg%LE_MAX(imat) = le_max
          ! Compute the equivalent non-local internal length
          CALL get_length(nloc_dmg%LEN(imat),nloc_dmg%LE_MAX(imat))
        ELSE
          ! Save the non-local internal length
          nloc_dmg%LEN(imat) = max(zero,rlen)
          ! Compute the corresponding maximal target element length
          CALL get_lemax(nloc_dmg%LE_MAX(imat),nloc_dmg%LEN(imat))
        ENDIF
        ! Flag for non-local material
        mat_param(imat)%NLOC = 1   
        ! Number of the material law
        ilaw = ipm(2,imat)       
        ! Flag of saving non-local plastic strain and strain rate in buffer
        mlaw_tag(imat)%G_PLANL  = 1
        mlaw_tag(imat)%L_PLANL  = 1
        mlaw_tag(imat)%G_EPSDNL = 1
        mlaw_tag(imat)%L_EPSDNL = 1                           
c--------------------------------------------------
c       Printout values
c--------------------------------------------------
        WRITE(iout,2000) mat_id,ilaw,nloc_dmg%LEN(imat),nloc_dmg%LE_MAX(imat)
c
      ENDDO
c-----------------------------------------      
 2000 FORMAT(/
     & 5x,'    NON-LOCAL REGULARIZATION  ',/,
     & 5x,'    ------------------------  ',/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . . . . =',i10/,
     & 5x,'MATERIAL LAW  . . . . . . . . . . . . . . . . =',i10/,
     & 5x,'NON-LOCAL INTERNAL LENGTH . . . . . . . . . . =',1pg20.13/,
     & 5x,'MAXIMAL ELEMENT LENGTH TARGET . . . . . . . . =',1pg20.13/)
c-----------------------------------------      
      RETURN
      END