hm_read_prop34.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_prop34           ../starter/source/properties/sph/hm_read_prop34.F
!||--- called by ------------------------------------------------------
!||    hm_read_prop_generic     ../starter/source/properties/hm_read_prop_generic.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    set_u_geo                ../starter/source/user_interface/uaccess.F
!||    set_u_pnu                ../starter/source/user_interface/uaccess.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_prop34(GEO, IGEO ,IOUT  ,NUVAR ,PARGEO,
     .                          QA, QB    ,ISKN  ,IG    ,TITR  ,UNITAB,
     .                          PROP_TAG,IGTYP,LSUBMODEL)
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE elbuftag_mod  
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "param_c.inc"
#include      "sphcom.inc"
#include      "tablen_c.inc"
C-----------------------------------------------
C   A n a l y s e   M o d u l e
C-----------------------------------------------
C----------+---------+---+---+--------------------------------------------
C VAR      | SIZE    |TYP| RW| DEFINITION
C----------+---------+---+---+--------------------------------------------
C IOUT     |  1      | I | R | OUTPUT FILE UNIT (L00 file)
C NUVAR    |  1      | I | W | NUMBER OF USER ELEMENT VARIABLES
C----------+---------+---+---+--------------------------------------------
C PARGEO   |  *      | F | W | 1)SKEW NUMBER
C          |         |   |   | 2)STIFNESS FOR INTERFACE
C          |         |   |   | 3)FRONT WAVE OPTION
C          |         |   |   | 4)... not yet used
C----------+---------+---+---+--------------------------------------------
C
C     This subroutine read the user geometry parameters.
C
C     The geometry datas has to bee stored in radioss storage
C     with the function SET_U_GEO(value_index,value).
C
C     If some standard radioss functions (time function or
C     x,y function) are used, this function IDs has to
C     bee stored with the function SET_U_PNU(func_index,func_id,KFUNC).
C
C     If this property refers to a user material, this
C     material IDs has to bee stored with the function
C     SET_U_PNU(mat_index,mat_id,KMAT).
C
C     If this property refers to a user property, this
C     sub-property IDs has to bee stored with the function
C     SET_U_PNU(sub_prop_index,sub_prop_id,KMAT).
C
C     SET_U_GEO and SET_U_PNU return 0 if no error
C     SET_U_GEO and SET_U_PNU return the maximum allowed index
C     if index is larger than this maximum
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT,NUVAR,ISKN(LISKN,*),IG,IGTYP,IGEO(*)
      CHARACTER(LEN=NCHARTITLE)::TITR
      my_real
     .        pargeo(*), geo(*)
      TYPE(prop_tag_) , DIMENSION(0:MAXPROP) :: PROP_TAG
      INTEGER SET_U_PNU,SET_U_GEO
      EXTERNAL set_u_pnu,set_u_geo
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
C=======================================================================
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IERROR,IORDER,ISK,K
      my_real
     .        xk,mp,qa,qb,alpcs,xorder,dist,pun,zstab,
     .        hmin,hmax,h_scal
      INTEGER IFLG_H
      my_real
     .   h_dilat_coeff,rflg_h
      LOGICAL IS_AVAILABLE, IS_ENCRYPTED
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      DATA pun/0.1/
C-----------------------------------------------
 
      nuvar=0
      pargeo(1) = 0
      xk=0.0
      pargeo(2)=xk
C     front wave=1
      pargeo(3) =1
C-------
      isk=0
      iflg_h=0
      iorder=-1
      dist  =zero
      zstab =zero
C
C--------------------------------------------------
C EXTRACT DATA (IS OPTION CRYPTED)
C--------------------------------------------------
      CALL hm_option_is_encrypted(is_encrypted)
C--------------------------------------------------
C EXTRACT DATAS (INTEGER VALUES)
C--------------------------------------------------
      CALL hm_get_intv('SKEW_CSID',isk,is_available,lsubmodel)
      CALL hm_get_intv('h_1D',iflg_h,is_available,lsubmodel)
      CALL hm_get_intv('ORDER',iorder,is_available,lsubmodel)
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
      CALL hm_get_floatv('MASS',mp,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('qa',qa,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('qb',qb,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('ALPHA1',alpcs,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('h',dist,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Xi_Stab',zstab,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('hmin',hmin,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('hmax',hmax,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('h_scal',h_scal,is_available,lsubmodel,unitab)
C----------------------
C
      WRITE(iout,1100) ig
 
      IF(qa==zero)qa=two
      IF(qb==zero)qb=one
      IF (zstab>0) nspbuf=15
C      
      IF (iflg_h == 3) THEN
        IF(hmin==zero) hmin = zep2
        IF(hmax==zero) hmax = two
        IF(h_scal==zero) h_scal = onep2
      ENDIF  
C
      IF(isk /= 0)THEN
        DO k=1,numskw
          IF(isk == iskn(4,k+1)) THEN
            pargeo(1)=(k+1)+pun
            GO TO 100
          ENDIF
        ENDDO
        CALL ancmsg(msgid=137,anmode=aninfo,msgtype=msgerror,
     .              c1='PROPERTY',
     .              c2='PROPERTY',
     .              i1=ig,i2=isk,c3=titr)
100     CONTINUE
      ELSE
        pargeo(1)=zero
        k = 1
      ENDIF
C------
C      IF(NSPMD > 1 .AND. IORDER==1)THEN
C        CALL ANCMSG(MSGID=755,
C     .              MSGTYPE=MSGERROR,
C     .              ANMODE=ANINFO,
C     .              C1='SPH CORRECTION ORDER 1')
C      END IF
C
      rflg_h = iflg_h
C
      IF (iflg_h==1) THEN
        h_dilat_coeff = one
      ELSEIF (iflg_h==2) THEN
        h_dilat_coeff = zero
      ELSE
        h_dilat_coeff = third
      ENDIF      
C
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'  CONFIDENTIAL DATA'
      ELSE
        IF(dist==zero)THEN
          WRITE(iout,1000)mp,qa,qb,alpcs,zstab,isk,iorder
          IF (iflg_h==3) THEN
            WRITE(iout,1005)
          ELSE   
            WRITE(iout,1004)
          ENDIF   
        ELSE
         WRITE(iout,1001)mp,qa,qb,alpcs,zstab,isk,iorder,dist
        ENDIF
        IF (iflg_h==1) THEN
          WRITE(iout,1002)
        ELSEIF (iflg_h==2) THEN
          WRITE(iout,1003)
        ELSEIF (iflg_h==3) THEN
          WRITE(iout,1006) hmin,hmax,h_scal
        END IF
      ENDIF
        
      IF(mp<=zero)THEN
        CALL ancmsg(msgid=138,anmode=aninfo,msgtype=msgwarning,
     .              c1=titr,i1=ig)
        mp=one
      ENDIF                      
C        
      ierror = set_u_geo(1,mp)
      ierror = set_u_geo(2,qa)
      ierror = set_u_geo(3,qb)
      ierror = set_u_geo(4,alpcs)
      xorder = iorder+em01
      ierror = set_u_geo(5,xorder)
      ierror = set_u_geo(6,dist)
      ierror = set_u_geo(7,zstab)
      ierror = set_u_geo(8,h_dilat_coeff)
      ierror = set_u_geo(9,rflg_h)     
      ierror = set_u_geo(10,hmin)
      ierror = set_u_geo(11,hmax)
      ierror = set_u_geo(12,h_scal)
C
      geo(14)=qa
      geo(15)=qb
      IF (geo(16) /= zero .OR. geo(17) /= zero) THEN
        igeo(33) = 1   ! ISVIS flag
      ENDIF         
C
      prop_tag(igtyp)%G_SIG  = 6
      prop_tag(igtyp)%G_VOL  = 1
      prop_tag(igtyp)%G_EINT = 1
      prop_tag(igtyp)%G_QVIS = 1
      prop_tag(igtyp)%L_SIG  = 6
      prop_tag(igtyp)%L_EINT = 1
      prop_tag(igtyp)%L_VOL  = 1
      prop_tag(igtyp)%L_QVIS = 1
C
      RETURN
C------
 999  CONTINUE
C      WRITE(IOUT,*)' **ERROR IN SPH PROPERTY INPUT.'
C      IERR=IERR+1
C      CALL ARRET(2)
      CALL ancmsg(msgid=401,
     .            msgtype=msgerror,
     .            anmode=aninfo,
     .            i1=ig,
     .            c2=titr,
     .            c1='SPH')
      RETURN
C------
 1000 FORMAT(
     & 5x,'PARTICLES MASS. . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'QA. . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'QB. . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'ALPCS . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'COEFFICIENT WRT TENSILE INSTABILITY . .=',1pg20.13/,
     & 5x,'ORTHOTROPIC INITIAL SKEW SYSTEM . . . .=',i10/,
     & 5x,'FORMULATION CORRECTION ORDER. . . . . .=',i10/,
     & 5x,'SMOOTHING LENGTH AUTOMATICALLY COMPUTED')
 1001 FORMAT(
     & 5x,'PARTICLES MASS. . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'QA. . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'QB. . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'ALPCS . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'COEFFICIENT WRT TENSILE INSTABILITY . .=',1pg20.13/,
     & 5x,'ORTHOTROPIC INITIAL SKEW SYSTEM . . . .=',i10/,
     & 5x,'FORMULATION CORRECTION ORDER. . . . . .=',i10/,
     & 5x,'SMOOTHING LENGTH. . . . . . . . . . . .=',1pg20.13)
 1002 FORMAT(
     & 5x,'UNIAXIAL DILATATION OF SMOOTHING LENGTH')
 1003 FORMAT(
     & 5x,'CONSTANT SMOOTHING LENGTH')
 1004 FORMAT(
     & 5x,'SMOOTHING LENGTH COMPUTED FROM PARTICLE MASS')
 1005 FORMAT(
     & 5x,'SMOOTHING LENGTH COMPUTED FROM INTERPARTICLE DISTANCE')    
 1006 FORMAT(
     & 5x,'BOUNDED DILATATION OF SMOOTHING LENGTH'/,
     & 5x,'MINIMUM DILATATION RATIO . . . . . . . =',1pg20.13/,
     & 5x,'MAXIMUM DILATATION RATIO . . . . . . . =',1pg20.13/,  
     & 5x,'SMOOTHING LENGTH SCALING FACTOR. . . . =',1pg20.13)        
 1100 FORMAT(
     & 5x,'SPH PROPERTY SET'/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10)
      END