hm_read_rand.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_rand           ../starter/source/general_controls/computation/hm_read_rand.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.f
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    ngr2usr                ../starter/source/system/nintrr.f
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    random_mod             ../starter/share/modules1/random_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_rand(X     ,IGRNOD   ,ITAB,IRAND,ALEA,XSEED,
     .                        UNITAB,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE unitab_mod
      USE random_mod
      USE names_and_titles_mod , ONLY : ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "scr03_c.inc"
#include      "random_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAB(*),IRAND(*)
      my_real
     .   x(3,*),alea(*),xseed(*)
C-----------------------------------------------
      TYPE (GROUP_)  ,TARGET, DIMENSION(NGRNOD)  :: IGRNOD
      TYPE (SUBMODEL_DATA),INTENT(IN)::LSUBMODEL(*)
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER  NGR2USR
      my_real
     .   aleat
      EXTERNAL ngr2usr,aleat
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,ID,IS,IGRS,IALL,NRANDG,SUB_ID
      CHARACTER(LEN=NCHARKEY) :: KEY
!
      INTEGER, DIMENSION(:), POINTER :: INGR2USR
      LOGICAL IS_AVAILABLE
C======================================================================|
      iall   = 0
      nrandg = 0
      seed  =zero
      xalea =zero
C--------------------------------------------------
C START BROWSING MODEL RBODY
C--------------------------------------------------
      is_available = .false.
      CALL hm_option_start('/RANDOM')
C-----------------------------      
      DO i=1,nrand
        irand(i) = 0
        alea(i) = zero
        xseed(i) = zero
        ! --------------------------------
        ! check if -rxalea or -rseed command line option are used
        IF(.NOT.rand_struct%CMD) THEN
C--------------------------------------------------
C EXTRACT DATAS OF /RANDOM
C--------------------------------------------------
            CALL hm_option_read_key(lsubmodel,
     .                           keyword2 = key, 
     .                           submodel_id = sub_id)
C
            IF(sub_id == 0) THEN
              CALL hm_get_floatv('XALEA',alea(i),is_available,lsubmodel,unitab)
              CALL hm_get_floatv('SEED',xseed(i),is_available,lsubmodel,unitab)
              CALL hm_get_intv('GRNOD_ID',id,is_available,lsubmodel)
C
              irand(i) = id
              IF (alea(i) > zero) THEN
                seed  = xseed(i) 
                IF(key(1:5) == 'GRNOD') THEN
                  nrandg = nrandg+1
                  ingr2usr => igrnod(1:ngrnod)%ID
                  irand(nrandg) = ngr2usr(id,ingr2usr,ngrnod)
                  IF (irand(nrandg) == 0) THEN       
                    CALL ancmsg(msgid=173,
     .                        msgtype=msgerror,
     .                          anmode=aninfo,
     .                          c1='RANDOM NOISE',
     .                          c2='NODE',
     .                          i1=id)
                    nrandg = nrandg-1
                  ENDIF
                ELSE
                  iall = iall+1               
                  xalea = alea(i)
                ENDIF                
              ENDIF 
            ENDIF 
        ! --------------------------------
        ELSE
        ! -rxalea or -rseed command line option are used
            iall = iall+1   
            irand(i) = 0
            alea(i) = rand_struct%ALEA_NBR
            xseed(i) = rand_struct%SEED_NBR
            seed = xseed(i) 
            xalea = alea(i)
        ENDIF     
        ! --------------------------------         
      ENDDO
      IF ((nrandg == 0 .AND. xalea > zero).OR.(nrandg > 0 .AND. iall == 0) ) THEN
        IF(.NOT.rand_struct%CMD) WRITE(iout,1000)
      ENDIF
C---
      IF (nrandg == 0 .AND. xalea > zero) THEN
C-----------------------
C       All nodes
C-----------------------
        DO i=1,numnod                
          x(1,i)=x(1,i)+xalea*aleat()
          x(2,i)=x(2,i)+xalea*aleat()
          x(3,i)=x(3,i)+xalea*aleat()
        ENDDO
C
        WRITE (iout,'(8X,A)')'NODE GROUP           :          ALL NODES'
        WRITE (iout,1100) xalea                                         
        IF (seed /= zero) WRITE (iout,1200) seed                        
        IF (ipri >= 4) THEN                                             
          WRITE (iout,1400)                                 
          DO i=1,numnod                                     
            WRITE(iout,1500)itab(i),x(1,i),x(2,i),x(3,i)   
          ENDDO                                             
        ENDIF                                                           
      ELSEIF (nrandg > 0 .AND. iall == 0) THEN
C-----------------------
C       Node groups only
C-----------------------
        DO i=1,nrandg                                                     
          igrs = irand(i)                                                 
          seed = xseed(i)
          DO j=1,igrnod(igrs)%NENTITY
            is=igrnod(igrs)%ENTITY(j)
            x(1,is)=x(1,is)+alea(i)*aleat()                                 
            x(2,is)=x(2,is)+alea(i)*aleat()                                 
            x(3,is)=x(3,is)+alea(i)*aleat()                                 
          ENDDO                                                           
          WRITE (iout,1050) igrnod(igrs)%ID
          WRITE (iout,1100) alea(i)                                          
          IF (seed /= zero) WRITE (iout,1200) seed                                              
        ENDDO
        IF (ipri >= 4) THEN                                               
          WRITE (iout,1400)                                               
          DO i=1,nrandg                                                   
            igrs = irand(i)                                      
            DO j=1,igrnod(igrs)%NENTITY
              is=igrnod(igrs)%ENTITY(j)
              WRITE(iout,1500) itab(is),x(1,is),x(2,is),x(3,is)                                
            ENDDO                                                          
          ENDDO                                                           
        ENDIF                                                    
      ENDIF                      
C-----------------------
      RETURN
 1000 FORMAT(//
     .'     RANDOM NOISE       '/
     .'     ------------       ')
 1050 FORMAT(/8x,'NODE GROUP           :          ID    = ',i10)
 1100 FORMAT( 8x,'MAXIMUM RANDOM NOISE :          XALEA = ',1pg20.13)
 1200 FORMAT( 8x,'RANDOM SEQUENCE      :          SEED  = ',1pg20.13)
 1400 FORMAT(/8x,'NEW NODE COORDINATES',20x,'X',24x,'Y',24x,'Z')
 1500 FORMAT( 7x,i10,3(5x,e20.13))
C---
      RETURN
      END SUBROUTINE hm_read_rand