i3sti2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    i3sti2                 ../starter/source/interfaces/inter2d1/i3sti2.F
!||--- called by ------------------------------------------------------
!||    inint2                 ../starter/source/interfaces/inter2d1/inint2.f
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    inare2                 ../starter/source/interfaces/inter2d1/inare2.F
!||    inori2                 ../starter/source/interfaces/inter2d1/inori2.F
!||    inrch2                 ../starter/source/interfaces/inter2d1/inrch2.F
!||    local_index            ../starter/source/interfaces/interf1/local_index.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i3sti2(
     1 X      ,IRECT   ,STF   ,IXQ     ,PM     ,
     2 NRT    ,STFN    ,NSEG  ,LNSV    ,NINT   ,
     3 NSN    ,NSV    ,SLSFAC ,NOINT   ,IPM    ,
     4 ID     ,TITR   ,AREAS  ,KNOD2ELQ,NOD2ELQ,
     5 NTY    ,NSNS   ,NSVS   ,SEGQUADFR)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NRT, NINT, NSN, NOINT, NTY, NSNS, IPM(NPROPMI,*)
      my_real
     .   SLSFAC
      INTEGER IRECT(4,*), IXQ(7,*), NSEG(*), LNSV(*), NSV(*),
     .        KNOD2ELQ(*),NOD2ELQ(*), NSVS(*), SEGQUADFR(2,*)
      my_real
     .   x(3,*), stf(*), pm(npropm,*), stfn(*),areas(*)
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, NEL, MT, J, NUM, NPT, JJ, LL, IG, IL, IE, INRT,
     .   n1 ,n2 ,stat, iline, lin, l, n, k
      INTEGER LINES(2,4)
      INTEGER, DIMENSION(:),ALLOCATABLE ::INRTIE
C     REAL
      my_real
     .   area, xl2, ym1, ym2, zm1, zm2,ye(4) ,ze(4),
     .   y1 ,y2 ,z1 ,z2
      DATA lines/1,2,
     .           2,3,
     .           3,4,
     .           4,1/
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
C
       ALLOCATE(inrtie(numelq),stat=stat)
       IF (stat /= 0) CALL ancmsg(msgid=268,anmode=aninfo,
     .                             msgtype=msgerror,
     .                         c1='INRTIE')
        inrtie(1:numelq)=0
C
      DO i=1,nrt
        ii=i
        CALL inrch2(x   , irect,ixq,  ii , nel,
     .              nint, ym1  ,ym2,  zm1,
     .              zm2 , ye   ,ze ,  id , titr)
        IF(nel/=0) THEN
         inrtie(nel) = ii
         CALL inare2(area,ye   ,ze)
         xl2=(ym2-ym1)**2+(zm2-zm1)**2
         mt=ixq(1,nel)
         IF(mt>0)THEN
          stf(i)=slsfac*xl2*pm(32,mt)/area
         ELSE
          stf(i)=zero
          CALL ancmsg(msgid=347,
     .                msgtype=msgwarning,
     .                anmode=aninfo_blind_2,
     .                i1=id,
     .                c1=titr,
     .                i2=ipm(1,mt),
     .                i3=nel,
     .                i4=i)
C
         ENDIF
        ELSE
          stf(i)=zero
        ENDIF
C
        CALL inori2(irect,ii,nel,nint,
     .              noint, ym1, ym2, zm1,zm2 ,
     .              ye   ,ze)
      ENDDO
C---------------------------------------------
C     CALCUL DES RIGIDITES NODALES
C---------------------------------------------
      DO j=1,nsn
        num=nseg(j+1)-nseg(j)
        npt=nseg(j)-1
        DO jj=1,num
          ll=lnsv(npt+jj)
          stfn(j)=stfn(j) + half*stf(ll)
        ENDDO
      ENDDO    
 
C---------------------------------------------
C     SECND NODAL SURFACE COMPUTATION
C---------------------------------------------
C
      IF(nty == 3) THEN
       DO i = 1,nsn    
         areas(i) = zero
         DO j= knod2elq(nsv(i))+1,knod2elq(nsv(i)+1)
            ie = nod2elq(j)
            inrt = inrtie(ie)
            IF(inrt/=0)THEN
               n1=irect(1,inrt)
               n2=irect(2,inrt)
               y1=x(2,n1)
               z1=x(3,n1)
               y2=x(2,n2)
               z2=x(3,n2)
c
               area = sqrt((y2-y1)*(y2-y1)+(z2-z1)*(z2-z1))
               area = area*half
c
              areas(i) = areas(i) + area
           ENDIF
          ENDDO
       ENDDO
      ELSEIF(nty == 5) THEN
       DO i = 1,nsns   
         areas(i) = zero
          DO j= knod2elq(nsvs(i))+1,knod2elq(nsvs(i)+1)
            ie = nod2elq(j)
            lin = -huge(lin)
            DO l=1,4 
              IF(ixq(lines(1,l)+1,ie) ==nsvs(i)) THEN
                 lin = l
                 EXIT
              ENDIF   
            ENDDO
 
           DO k=1,nsegquadfr
              n  =segquadfr(1,k)
              iline=segquadfr(2,k)
              
              IF(n==ie.AND.iline==lin) THEN
 
                n1=ixq(lines(1,iline)+1,n)
                n2=ixq(lines(2,iline)+1,n)
 
               y1=x(2,n1)
               z1=x(3,n1)
               y2=x(2,n2)
               z2=x(3,n2)
 
              area = sqrt((y2-y1)*(y2-y1)+(z2-z1)*(z2-z1))
              area = area*half
 
              areas(i) = areas(i) + area
             ENDIF
           ENDDO
          ENDDO
        ENDDO
      ENDIF
      DEALLOCATE(inrtie)
 
C-----------------------------------------------------
C     MISE DANS IRECT DU NUMERO LOCAL DU NOEUD
C-----------------------------------------------------
      DO i=1,nrt
        ig=irect(1,i)
        CALL local_index(il,ig,nsv,nsn)
        irect(1,i)=il
        ig=irect(2,i)
        CALL local_index(il,ig,nsv,nsn)
        irect(2,i)=il
      ENDDO
C
      RETURN
      END