lecstamp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
CCgw|         LECTUR                         /lectur1/lectur.F
!||====================================================================
!||    lecstamp               ../starter/source/interfaces/interf1/lecstamp.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    fretitl2               ../starter/source/starter/freform.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.f
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    ifrontplus             ../starter/source/spmd/node/frontplus.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    intstamp_mod           ../starter/share/modules1/intstamp_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE lecstamp(IPARI  ,INTSTAMP, UNITAB, NPBY,
     .                    ICODE  ,NOM_OPT ,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE intstamp_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER NOM_OPT(LNOPT1,*)
      INTEGER IPARI(NPARI,*), NPBY(NNPBY,*), 
     .        icode(numnod)
      TYPE(intstamp_data) INTSTAMP(*)
      TYPE(submodel_data) LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J, L, NI, NIN, N,
     .   ntyp,noint,nstamp,irot,
     .   iflagunit,uid,flag_fmt,flag_fmt_tmp,ifix_tmp,
     .   id_intdamp,intdamp, irb, msr, p, ic, sub_id
      my_real
     .   fac_l,fac_t,fac_m,fac_i,
     .   damp, dampr
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARKEY) :: KEY
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS
      DATA mess/'INTERFACE INPUT                         '/
C=======================================================================
 
      ni= 0
      nstamp = 0
C
C--------------------------------------------------
C START BROWSING MODEL INTERFACES
C--------------------------------------------------
      CALL hm_option_start('/INTER')
C--------------------------------------------------
C BROWSING MODEL INTERFACES 1->HM_NINTER
C--------------------------------------------------
      DO nin=1,hm_ninter
C
C--------------------------------------------------
C EXTRACT DATAS OF /INTER/... LINE
C--------------------------------------------------
        CALL hm_option_read_key(lsubmodel,
     .                       option_id = noint,
     .                       unit_id = uid,
     .                       submodel_id = sub_id,
     .                       option_titr = titr,
     .                       keyword2 = key)
C--------------------------------------------------
C CHECK IF READ OPTION IS /INTER/SUB
C--------------------------------------------------
        IF(key(1:len_trim(key))=='SUB') cycle 
C--------------------------------------------------
         ni=ni+1
C
        ntyp   = ipari(7,ni)
        noint  = ipari(15,ni)
C
        IF (ntyp == 21) THEN
 
          nstamp=nstamp+1
          intstamp(nstamp)%NOINTER=ni
 
          WRITE(iout,2100) noint
          is_available = .false.
c associated rbody
          CALL hm_get_intv('ID_RBY',intstamp(nstamp)%IRB,is_available,lsubmodel)
          CALL hm_get_intv('InterfaceId',id_intdamp,is_available,lsubmodel)
          CALL hm_get_floatv('DAMP1',damp,is_available,lsubmodel,unitab)
          CALL hm_get_floatv('DAMP2',dampr,is_available,lsubmodel,unitab)
 
C associated rbody & main node
          irb=0
          DO n=1,nrbody
            IF(intstamp(nstamp)%IRB==npby(6,n))THEN
              IF(npby(12,n) == 0) THEN
                irb=n
                EXIT
              ELSE
                CALL ancmsg(msgid=1635,
     .                      msgtype=msgerror,
     .                      anmode=anstop,
     .                      i1=noint,
     .                      c1=titr,
     .                      i2=intstamp(nstamp)%IRB)
              ENDIF
            END IF
          END DO
          IF(irb==0)THEN
            CALL ancmsg(msgid=684,
     .                  msgtype=msgerror,
     .                  anmode=anstop,
     .                   i1=noint,
     .                   c1=titr,
     .                   i2=intstamp(nstamp)%IRB)
          END IF
          intstamp(nstamp)%IRB=irb
          intstamp(nstamp)%MSR=npby(1,irb)
          DO p = 1, nspmd
                CALL ifrontplus(npby(1,irb),p)
          ENDDO
C
          WRITE(iout,2111) id_intdamp,damp
          intstamp(nstamp)%INTDAMP=id_intdamp
          intstamp(nstamp)%DAMP=damp
          irot=1
          ic=mod(icode(npby(1,irb)),512)
          IF(ic==448)irot=0
          IF(irot/=0)THEN
            WRITE(iout,2112) dampr
            intstamp(nstamp)%DAMPR=dampr
          END IF
          intstamp(nstamp)%IROT=irot
        END IF
      END DO
C-----
      DO nin=1,nstamp
        id_intdamp=intstamp(nin)%INTDAMP
        IF(id_intdamp==0) GOTO 110
        DO j=1,nstamp
          IF(ipari(15,intstamp(j)%NOINTER)==id_intdamp)THEN
            intstamp(nin)%INTDAMP=j
            GOTO 110
          END IF
        END DO
        CALL fretitl2(titr,
     .       nom_opt(lnopt1-ltitr+1,nin),ltitr)
        CALL ancmsg(msgid=868,
     .              msgtype=msgerror,
     .              anmode=aninfo_blind_1,
     .              i1=nom_opt(1,nin),
     .              c1=titr,
     .              i2=id_intdamp)
  110   CONTINUE
      END DO
C-----
 2100 FORMAT(//
     .       '  ADDITIONAL INFO FOR INTERFACE ID. . . . . .',i1/,
     .       '                      INTERFACE TYPE. . . . .21',/)
 2111 FORMAT('  DAMPING WRT REFERENCE INTERFACE . . . . . . .',i10/,
     .       '           (0: DAMPING WRT GLOBAL FRAME). . . .',/,
     .       '  TRANSLATIONAL CRITICAL DAMPING FACTOR . . . .',
     .        1pg20.13/)
 2112 FORMAT('  ROTATIONAL CRITICAL DAMPING FACTOR. . . . . .',
     .        1pg20.13/)
C-----
      RETURN
      END