lszk.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "param_c.inc"
#include "com04_c.inc"
#include "com06_c.inc"
#include "com08_c.inc"
#include "vect01_c.inc"
#include "scr06_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	lszk (iflag, nel, pm, off, eint, mu, espe, dvol, df, vnew, mat, psh, pnew, dpdm, dpde)

Function/Subroutine Documentation

lszk()

subroutine lszk	(	integer	iflag,
		integer	nel,
			pm,
			off,
			eint,
			mu,
			espe,
			dvol,
			df,
			vnew,
		integer, dimension(nel)	mat,
			psh,
			pnew,
			dpdm,
			dpde )

Definition at line 28 of file lszk.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
C
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of LSZK EOS
C Landau Stanyukovich Zeldovich Kompaneet
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
#include      "scr06_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER MAT(NEL), IFLAG, NEL
        my_real pm(npropm,nummat),
     .          off(nel)  ,eint(nel) ,mu(nel)   ,
     .          espe(nel) ,dvol(nel) ,df(nel)  ,
     .          vnew(nel) ,pnew(nel) ,dpdm(nel),
     .          dpde(nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I, MX
        my_real :: p0,psh(nel),gamma,e0,aa,bb,dvv,pp,ar0b,b,pc
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
        IF(iflag == 0) THEN
          mx         = mat(1)
          e0         = pm(23,mx)
          gamma      = pm(34,mx)
          p0         = pm(32,mx)
          psh(1:nel) = pm(88,mx)
          ar0b       = pm(35,mx)
          b          = pm(36,mx)
          pc         = pm(37,mx)
          DO i=1,nel
            pp      = (gamma-one)*(one+mu(i))*espe(i) + ar0b*exp(b*log(one+mu(i)))
            dpdm(i) = (gamma-one)*espe(i)+ar0b*b/(one+mu(i))*exp((b-one)*log(one+mu(i)))+(gamma-one)*df(i)*pp   !total derivative
            dpde(i) = (gamma-one)*(one+mu(i))                                                                   !partial derivative
            pnew(i) = max(pp,pc)*off(i)  ! P(mu[n+1],E[n])
            pnew(i) = pnew(i) - psh(i)
          ENDDO
 
        ELSEIF(iflag == 1) THEN
          mx         = mat(1)
          e0         = pm(23,mx)
          gamma      = pm(34,mx)
          p0         = pm(32,mx)
          psh(1:nel) = pm(88,mx)
          ar0b       = pm(35,mx)
          b          = pm(36,mx)
          pc         = pm(37,mx)
          DO i=1,nel
            bb         = (gamma-one)*(one+mu(i))
            dpde(i)    = bb
            aa         = ar0b*exp(b*log(one+mu(i)))
            dvv        = half*dvol(i)*df(i) / max(em15,vnew(i))
            pnew(i)    = (aa + bb*espe(i) ) / (one+bb*dvv)
            pnew(i)    = max(pnew(i),pc)*off(i)   ! P(mu[n+1],E[n+1])
            eint(i)    = eint(i) - half*dvol(i)*(pnew(i))
            pnew(i)    = pnew(i) - psh(i)
          ENDDO
 
        ELSEIF (iflag == 2) THEN
          mx           = mat(1)
          e0           = pm(23,mx)
          gamma        = pm(34,mx)
          p0           = pm(32,mx)
          psh(1:nel) = pm(88,mx)
          ar0b         = pm(35,mx)
          b            = pm(36,mx)
          DO i=1, nel
            IF (vnew(i) > zero) THEN
              pnew(i) = (gamma-one)*(one+mu(i))*espe(i) + ar0b*exp(b*log(one+mu(i)))
              dpdm(i) = (gamma-one)*espe(i)+ar0b*b/(one+mu(i))*exp((b-one)*log(one+mu(i)))+(gamma-one)*df(i)*pnew(i)   !total derivative
              dpde(i) = (gamma-one)*(one+mu(i))                                                               !partial derivative
              pnew(i) = pnew(i)-psh(i)
            ENDIF
          ENDDO
 
        ENDIF
 
C-----------------------------------------------
        RETURN