osborne_mod Module Reference

Functions/Subroutines
subroutine	osborne (iflag, nel, pmin, off, eint, mu, espe, dvol, df, vnew, rho0, psh, pnew, dpdm, dpde, eos_struct)

Function/Subroutine Documentation

osborne()

subroutine osborne_mod::osborne	(	integer, intent(in)	iflag,
		integer, intent(in)	nel,
		intent(in)	pmin,
		dimension(nel), intent(in)	off,
		dimension(nel), intent(inout)	eint,
		dimension(nel), intent(in)	mu,
		dimension(nel), intent(inout)	espe,
		dimension(nel), intent(in)	dvol,
		dimension(nel), intent(in)	df,
		dimension(nel), intent(in)	vnew,
		dimension(nel), intent(in)	rho0,
		dimension(nel), intent(inout)	psh,
		dimension(nel), intent(inout)	pnew,
		dimension(nel), intent(inout)	dpdm,
		dimension(nel), intent(inout)	dpde,
		type(eos_param_), intent(in)	eos_struct )

Definition at line 41 of file osborne.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE eos_param_mod , ONLY : eos_param_
      USE constant_mod , ONLY : em15,zero,one,half,two
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine contains numerical solving
C of OSBORNE EOS
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
      IMPLICIT NONE
#include    "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IFLAG, NEL
      my_real,INTENT(IN) :: off(nel) ,mu(nel) ,dvol(nel) ,df(nel) ,vnew(nel), rho0(nel), pmin
      my_real,INTENT(INOUT) :: pnew(nel), dpdm(nel), dpde(nel),psh(nel),eint(nel),espe(nel)
      TYPE(EOS_PARAM_),INTENT(IN):: EOS_STRUCT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER I
        my_real :: p0,e0,dvv,pp,dpdmu
        my_real :: a1,a2,b0,b1,b2,c0,c1,d0, a2_
        my_real :: denom
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
        e0         = eos_struct%E0
        psh(1:nel) = eos_struct%PSH
 
        a1 = eos_struct%UPARAM(1)
        a2 = eos_struct%UPARAM(2)
        b0 = eos_struct%UPARAM(3)
        b1 = eos_struct%UPARAM(4)
        b2 = eos_struct%UPARAM(5)
        c0 = eos_struct%UPARAM(6)
        c1 = eos_struct%UPARAM(7)
        d0 = eos_struct%UPARAM(8)
        p0 = eos_struct%UPARAM(9)
 
      IF(iflag == 0) THEN
        DO i=1,nel
          a2_=a2
          IF(mu(i)<zero)a2_=-a2
          denom   = (espe(i)+d0)
          pp      = (a1*mu(i)+a2_*mu(i)*mu(i)+(b0+b1*mu(i)+b2*mu(i)*mu(i))*espe(i)+(c1*mu(i)+c0)*espe(i)*espe(i))/denom
          pp      = max(pp,pmin) * off(i)
          dpdmu   = (a1+2*a2_*mu(i)+(two*b2*mu(i)+b1)*espe(i)+c1*espe(i)*espe(i))/denom
          dpde(i) = (((b2*mu(i)+b1)*mu(i)+b0)+(two*(c1*mu(i)+c0))*espe(i) - pp/denom)/denom
          dpdm(i) = dpdmu + dpde(i)*df(i)*df(i)*(pp)   !total derivative
          pnew(i) = pp ! P(mu[n+1],E[n])
          pnew(i) = pnew(i) - psh(i)
        ENDDO
 
      ELSEIF(iflag == 1) THEN
        DO i=1,nel
          a2_=a2
          IF(mu(i)<zero)a2_=-a2
          dvv      = dvol(i)*df(i) / max(em15,vnew(i))   ! DVOL/V0  car  ESPE =EINT/V0
          dvv      = half*dvv ! car 2 iterations
          denom   = (espe(i)+d0)
          pp      = (a1*mu(i)+a2_*mu(i)*mu(i)+(b0+b1*mu(i)+b2*mu(i)*mu(i))*espe(i)+(c1*mu(i)+c0)*espe(i)*espe(i))/denom
          pp      = max(pp,pmin) * off(i)
          espe(i) = espe(i) - (pp)*dvv
          denom   = (espe(i)+d0)
          pp      = (a1*mu(i)+a2_*mu(i)*mu(i)+(b0+b1*mu(i)+b2*mu(i)*mu(i))*espe(i)+(c1*mu(i)+c0)*espe(i)*espe(i))/denom
          pp      = max(pp,pmin) * off(i)
          espe(i) = espe(i) - (pp)*dvv
          pnew(i) = pp ! P(mu[n+1],E[n+1])
          eint(i) = eint(i) - half*dvol(i)*(pnew(i))
          pnew(i) = pnew(i) - psh(i)
          dpde(i) = (((b2*mu(i)+b1)*mu(i)+b0)+(two*(c1*mu(i)+c0))*espe(i) - pp/denom)/denom
        ENDDO
 
      ELSEIF(iflag == 2) THEN
        DO i=1, nel
          IF (vnew(i) > zero) THEN
            a2_=a2
            IF(mu(i)<zero)a2_=-a2
            denom   = (espe(i)+d0)
            pp      = (a1*mu(i)+a2_*mu(i)*mu(i)+(b0+b1*mu(i)+b2*mu(i)*mu(i))*espe(i)+(c1*mu(i)+c0)*espe(i)*espe(i))/denom
            pp      = max(pp,pmin)*off(i)
            dpdmu   = (a1+2*a2_*mu(i)+(two*b2*mu(i)+b1)*espe(i)+c1*espe(i)*espe(i))/denom
            dpde(i) = (((b2*mu(i)+b1)*mu(i)+b0)+(two*(c1*mu(i)+c0))*espe(i) - pp/denom)/denom
            dpdm(i) = dpdmu + dpde(i)*df(i)*df(i)*(pp) !total derivative
            pnew(i) = pp
            pnew(i) = pnew(i) - psh(i)
          ENDIF
        ENDDO
 
        ENDIF
 
C-----------------------------------------------
        RETURN