new_seatbelt.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"
#include "com04_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	new_seatbelt (ixr, itab, knod2el1d, nod2el1d, nod_start, elem_cur, tag_res, tag_nod, id, flag, nnod, ipm, nb_elem_1d, nb_branch, branch_tab, branch_cpt)

Function/Subroutine Documentation

new_seatbelt()

subroutine new_seatbelt	(	integer, dimension(nixr,*)	ixr,
		integer, dimension(*)	itab,
		integer, dimension(*)	knod2el1d,
		integer, dimension(*)	nod2el1d,
		integer	nod_start,
		integer	elem_cur,
		integer, dimension(*)	tag_res,
		integer, dimension(*)	tag_nod,
		integer	id,
		integer	flag,
		integer	nnod,
		integer, dimension(npropmi,*)	ipm,
		integer, intent(in)	nb_elem_1d,
		integer, intent(inout)	nb_branch,
		integer, dimension(2*nb_elem_1d), intent(inout)	branch_tab,
		integer, intent(inout)	branch_cpt )

Definition at line 33 of file new_seatbelt.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE seatbelt_mod
      use element_mod , only : nixr
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXR(NIXR,*),ITAB(*),KNOD2EL1D(*),NOD2EL1D(*),NOD_START,TAG_RES(*),TAG_NOD(*),
     .        ELEM_CUR,ID,FLAG,NNOD,IPM(NPROPMI,*)
      INTEGER, INTENT(IN)    :: NB_ELEM_1D
      INTEGER, INTENT(INOUT) :: NB_BRANCH,BRANCH_TAB(2*NB_ELEM_1D),BRANCH_CPT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER K,NODE_CUR,NRES_FOUND,NODE_NEXT,ELEM_NEXT,ID_PREV,MTYP,MID,ELEM_TEST
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
C
C--   Loop to find elements of the seatbelt 
C
      node_cur = nod_start
      elem_next = 0
      IF (flag == 0) tag_res(elem_cur) = id
      tag_nod(ixr(2,elem_cur)) = id
      tag_nod(ixr(3,elem_cur)) = id
      nnod = nnod + 1
      nres_found = 1
C
      DO WHILE (nres_found > 0)
        nres_found = 0
C
        IF (ixr(2,elem_cur) == node_cur) THEN
          node_next = ixr(3,elem_cur)
        ELSE
          node_next = ixr(2,elem_cur)
        ENDIF
C     
        DO k=knod2el1d(node_next)+1,knod2el1d(node_next+1)
          IF ((nod2el1d(k) > numelt+numelp).AND.(nod2el1d(k) /= elem_cur+numelt+numelp)) THEN
            elem_test = nod2el1d(k)-numelt-numelp
            mid = ixr(5,elem_test)
            IF (mid > 0) THEN
              mtyp = ipm(2,mid)
              IF ((mtyp == 114).AND.(tag_res(elem_test) == 0)) THEN
                nres_found = nres_found + 1
                IF(nres_found > 1) THEN
                  IF (flag > 0) THEN
C--                 loop inisde retractor : bifurcation is not allowded inside retractor or at entry
                    CALL ancmsg(msgid=2005,
     .                         msgtype=msgerror,
     .                         anmode=aninfo,
     .                         i1=itab(node_next))
                    nres_found = 0
                  ELSE
C--                 start of the secondary branch is saved
                    nb_branch = nb_branch + 1
                    branch_cpt = branch_cpt + 1
                    CALL ancmsg(msgid=2098,
     .                          msgtype=msgwarning,
     .                          anmode=aninfo,
     .                          i1=itab(node_next))
                    branch_tab(2*(branch_cpt-1)+1) = node_next
                    branch_tab(2*(branch_cpt-1)+2) = elem_test
                  ENDIF
                ELSE
                  elem_next = elem_test
                ENDIF
              ENDIF
            ENDIF
          ENDIF
        ENDDO
C       Exit loop if node is a connection between 1D and 2D seatblet
        IF (nres_found > 0) THEN
          DO k=1,n_comn_1d2d
            IF (node_next == comn_1d2d(k)) nres_found=0
          ENDDO 
        ENDIF  
C
        IF (nres_found > 0) THEN
          IF (flag == 0) THEN
            tag_res(elem_next) = id
            tag_nod(ixr(2,elem_next)) = id
            tag_nod(ixr(3,elem_next)) = id
            nnod = nnod + 1
          ELSE
            IF (tag_res(elem_next) > 0) THEN
              id_prev = retractor(tag_res(elem_next))%ID
              IF ((id_prev > 0).AND.(nres_found > 0)) CALL ancmsg(msgid=2010,
     .                                            msgtype=msgerror,
     .                                            anmode=aninfo,
     .                                            i1=id_prev,i2=ixr(nixr,elem_next),i3=retractor(id)%ID)
            ENDIF
            tag_res(elem_next) = id
            tag_nod(ixr(2,elem_next)) = id
            tag_nod(ixr(3,elem_next)) = id
          ENDIF
        ENDIF
C       
        elem_cur = elem_next
        node_cur = node_next
      ENDDO                      
C