pcurv3.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"
#include "com08_c.inc"
#include "param_c.inc"
#include "impl1_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	pcurv3 (r, geo, offg, off, exx, exy, exz, kxx, kyy, kzz, al, nc1, nc2, nc3, rx1g, rx2g, ry1g, ry2g, rz1g, rz2g, e1x, e1y, e1z, e2x, e2y, e2z, e3x, e3y, e3z, pid, nel)

Function/Subroutine Documentation

pcurv3()

subroutine pcurv3	(		r,
			geo,
			offg,
			off,
			exx,
			exy,
			exz,
			kxx,
			kyy,
			kzz,
			al,
		integer, dimension(mvsiz)	nc1,
		integer, dimension(mvsiz)	nc2,
		integer, dimension(mvsiz)	nc3,
			rx1g,
			rx2g,
			ry1g,
			ry2g,
			rz1g,
			rz2g,
			e1x,
			e1y,
			e1z,
			e2x,
			e2y,
			e2z,
			e3x,
			e3y,
			e3z,
		integer, dimension(mvsiz)	pid,
		integer, intent(in)	nel )

Definition at line 28 of file pcurv3.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "param_c.inc"
#include      "impl1_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ),PID(MVSIZ)
      my_real
     .   r(3,*), geo(npropg,*),
     .   offg(*),off(*),al(mvsiz),exx(mvsiz),exy(mvsiz),exz(mvsiz),
     .   kxx(mvsiz),kyy(mvsiz),kzz(mvsiz),rx1g(mvsiz),rx2g(mvsiz),
     .   ry1g(mvsiz),ry2g(mvsiz),rz1g(mvsiz),rz2g(mvsiz),
     .   rx1(mvsiz),rx2(mvsiz),ry1(mvsiz),ry2(mvsiz),rz1(mvsiz),rz2(mvsiz),
     .   e1x(mvsiz),e1y(mvsiz),e1z(mvsiz),e2x(mvsiz),e2y(mvsiz),
     .   e2z(mvsiz),e3x(mvsiz),e3y(mvsiz),e3z(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, IG, IRX, IR1Y, IR1Z,
     .   IR2Y, IR2Z, IRY, IRZ, J
      my_real
     .   rxav(mvsiz), ryav(mvsiz), rzav(mvsiz),exx00(mvsiz), exy00(mvsiz), 
     .   exz00(mvsiz), exy0(mvsiz), exz0(mvsiz),rz10(mvsiz),
     .   ry10(mvsiz), rz20(mvsiz), ry20(mvsiz), exx00phi,exy00phi, 
     .   exz00phi, exy0phi, exz0phi, rx10phi, ry10phi, rz10phi, 
     .   rx20phi, ry20phi, rz20phi,off_l,dt05   
C-----------------------------------------------
      DO i=1,nel
        rx1(i)=e1x(i)*rx1g(i)+e1y(i)*ry1g(i)+e1z(i)*rz1g(i)
        ry1(i)=e2x(i)*rx1g(i)+e2y(i)*ry1g(i)+e2z(i)*rz1g(i)
        rz1(i)=e3x(i)*rx1g(i)+e3y(i)*ry1g(i)+e3z(i)*rz1g(i)
        rx2(i)=e1x(i)*rx2g(i)+e1y(i)*ry2g(i)+e1z(i)*rz2g(i)
        ry2(i)=e2x(i)*rx2g(i)+e2y(i)*ry2g(i)+e2z(i)*rz2g(i)
        rz2(i)=e3x(i)*rx2g(i)+e3y(i)*ry2g(i)+e3z(i)*rz2g(i)
      ENDDO
C---------------------------------
C     SECOND ORDRE TRANSLATIONS ROTATIONS
C---------------------------------
      dt05=half*dt1
      IF (impl_s > 0 .AND. ismdisp > 0) dt05=zero
C
      DO i=1,nel
        rxav(i)= half*dt05*(rx1(i)+rx2(i))
        exx00(i)=exx(i)
        exy00(i)=exy(i)
        exz00(i)=exz(i)
C
        exy0(i)=dt05*exy(i)
        exz0(i)=dt05*exz(i)
        exx(i)=exx(i)-(exy0(i)*exy00(i)+exz0(i)*exz00(i))
        exy(i)=exy(i)+exz0(i)*exx00(i)
        exz(i)=exz(i)+exy0(i)*exx00(i)
        rz10(i)=rz1(i)
        ry10(i)=ry1(i)
        rz20(i)=rz2(i)
        ry20(i)=ry2(i)
        rx1(i)=rx1(i)-exy0(i)*ry10(i)-exz0(i)*rz10(i)
        ry1(i)=ry1(i)-rxav(i)*(rz10(i)-exy(i))
        rz1(i)=rz1(i)+rxav(i)*(ry10(i)+exz(i))
        rx2(i)=rx2(i)-exy0(i)*ry20(i)-exz0(i)*rz20(i)
        ry2(i)=ry2(i)-rxav(i)*(rz20(i)-exy(i))
        rz2(i)=rz2(i)+rxav(i)*(ry20(i)+exz(i))
      ENDDO
C---------------------------------------------------
C     LIBERATION DES ROTATIONS
C---------------------------------------------------
      DO i=1,nel
        ig=pid(i)
        irx =nint(geo(7 ,ig))
        ir1y=nint(geo(8 ,ig))
        ir1z=nint(geo(9 ,ig))
        ir2y=nint(geo(10,ig))
        ir2z=nint(geo(11,ig))
        iry =min(1,ir1y+ir2y)
        irz =min(1,ir1z+ir2z)
        rx1(i)=rx1(i)*irx
        ry1(i)=ry1(i)*iry
        rz1(i)=rz1(i)*irz
        rx2(i)=rx2(i)*irx
        ry2(i)=ry2(i)*iry
        rz2(i)=rz2(i)*irz
        exz(i)=exz(i)*iry
        exy(i)=exy(i)*irz
C ... !!!!!!!
        ry1(i)=ir1y*ry1(i)
     +         -(one -ir1y)*(three_half*exz(i)+half*ry2(i))
        ry2(i)=ir2y*ry2(i)
     +         -(one -ir2y)*(three_half*exz(i)+half*ry1(i))
        rz1(i)=ir1z*rz1(i)
     +         +(one-ir1z)*(three_half*exy(i)-half*rz2(i))
        rz2(i)=ir2z*rz2(i)
     +         +(one -ir2z)*(three_half*exy(i)-half*rz1(i))
      ENDDO
C
      DO i=1,nel
        kxx(i)=(rx2(i)-rx1(i))/al(i)
        kyy(i)=(ry2(i)-ry1(i))/al(i)
        kzz(i)=(rz2(i)-rz1(i))/al(i)
      ENDDO
C
      DO i=1,nel
        rxav(i)=rx1(i)+rx2(i)
        rzav(i)=rz1(i)+rz2(i)
        ryav(i)=ry1(i)+ry2(i)
      ENDDO
C---------------------------------
      DO i=1,nel
        exz(i)=exz(i) + half*ryav(i)
        exy(i)=exy(i) - half*rzav(i)
      ENDDO
C----------------------------
C     OFF
C----------------------------
      off_l = zero
      DO i=1,nel
        off(i) = min(one,abs(offg(i)))
        off(i) = max(zero,off(i))
        off_l  = min(off_l,offg(i))
      ENDDO
      IF (off_l < zero) THEN
        DO i=1,nel
          IF (offg(i) < zero) THEN
            exx(i)=zero
            exz(i)=zero
            exy(i)=zero
            kxx(i)=zero
            kyy(i)=zero
            kzz(i)=zero   
          ENDIF
        ENDDO
      ENDIF
C---------------------------------
      RETURN