read_dfs_wave_shaper.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_dfs_wave_shaper     ../starter/source/initial_conditions/detonation/read_dfs_wave_shaper.f
!||--- called by ------------------------------------------------------
!||    read_detonators          ../starter/source/initial_conditions/detonation/read_detonators.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    hm_option_read_key       ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start          ../starter/source/devtools/hm_reader/hm_option_start.F
!||    ifrontplus               ../starter/source/spmd/node/frontplus.F
!||    nintri                   ../starter/source/system/nintrr.F
!||    nodgrnr5                 ../starter/source/starter/freform.F
!||    unused_mat_detonator     ../starter/source/initial_conditions/detonation/unused_mat_detonator.F
!||    usr2sys                  ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    detonators_mod           ../starter/share/modules1/detonators_mod.F
!||    format_mod               ../starter/share/modules1/format_mod.F90
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE read_dfs_wave_shaper(DETONATORS,IGRNOD,IPM,ITABM1,UNITAB,LSUBMODEL,ITAB)
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE unitab_mod
      USE message_mod
      USE detonators_mod
      USE groupdef_mod
      USE hm_option_read_mod
      USE submodel_mod
      USE detonators_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
      USE format_mod , ONLY : fmw_10i
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
#include      "param_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN)                  :: UNITAB
      INTEGER,INTENT(IN)                            :: ITABM1(SITABM1),ITAB(NUMNOD)
      INTEGER,INTENT(IN)                            :: IPM(NPROPMI,NUMMAT)
      TYPE(submodel_data),INTENT(IN)                :: LSUBMODEL(NSUBMOD)
      TYPE(detonators_struct_),INTENT(INOUT),TARGET :: DETONATORS
      TYPE (GROUP_),DIMENSION(NGRNOD),INTENT(IN)    :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER              :: I, MAT, J, K,IGU,IGS,JJ,MDET,DET_ID,IDET
      INTEGER              :: IBID,  NODE_ID1, NODE_ID2,uID1,uID2, IOPT, IUNIT, UID
      INTEGER              :: FLAG_FMT,IMAT,IFLAGUNIT,UNUSED
      INTEGER              :: STAT,NPE
      my_real              :: xc, yc, zc, alt, xc1, yc1, zc1, xc2, yc2, zc2, nx, ny, nz, bid, vcj, vdet
      CHARACTER*40         :: MESS
      CHARACTER*64         :: chain1,chain2
      CHARACTER(LEN=NCHARKEY) :: KEY, KEY2
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL              :: IS_ENCRYPTED, IS_AVAILABLE
      INTEGER,POINTER,DIMENSION(:) :: IECRAN
      my_real,POINTER,DIMENSION(:) :: decran
      INTEGER              :: NDETPS,NDETSG,NECRAN,NDETPL,NDETCORD
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER,EXTERNAL  :: NODGRNR5, USR2SYS, NINTRI
      INTEGER           :: UNUSED_MAT_DETONATOR
      DATA mess/'DETONATORS DEFINITION                   '/      
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
      CALL hm_option_start('/DFS/WAV_SHA')
 
      DO idet=1,detonators%N_DET_WAVE_SHAPER
 
        CALL hm_option_read_key(lsubmodel,option_id=det_id, unit_id=uid,keyword2=key,keyword3=key2)
        IF (len_trim(key) > 0) key = key(1:7)
        IF (len_trim(key2) > 0) key2 = key2(1:4)
 
        iecran => detonators%WAVE_SHAPER(idet)%NODES(1:)
        decran => detonators%WAVE_SHAPER(idet)%TIME(1:)
 
        is_encrypted= .false.
        is_available = .false.
        CALL hm_option_is_encrypted(is_encrypted)
        !---------------------------------!
        !             READING             !
        !---------------------------------!
        CALL hm_get_floatv('rad_det_locationA_X', vdet, is_available, lsubmodel, unitab)
        CALL hm_get_floatv('rad_det_locationA_Y', yc1, is_available, lsubmodel, unitab)
        CALL hm_get_floatv('rad_det_locationA_Z', zc1, is_available, lsubmodel, unitab)
        CALL hm_get_floatv('rad_det_time', alt, is_available, lsubmodel,unitab)
        CALL hm_get_intv('rad_det_materialid', mat, is_available, lsubmodel)
        CALL hm_get_intv('entityid', igu, is_available, lsubmodel)
        !---------------------------------!
        !      CHECKING USER FLAGS        !
        !      +INTERNAL ID               !
        !---------------------------------!
        mdet=mat !bak
        IF (alt > infinity) alt=infinity
        IF(mat > 0)unused=unused_mat_detonator(mat,nummat,ipm)
        unused=0
        IF (mat < 0) THEN
          CALL ancmsg(msgid=102,msgtype=msgerror,anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR IS REFERRING TO A NEGATIVE MATERIAL ID',
     .                c2='/DFS/WAV_SHA',
     .                i2=mdet)
        ELSEIF (unused==1) THEN
          CALL ancmsg(msgid=102,msgtype=msgerror,anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR IS REFERRING TO AN UNKNOWN MATERIAL ID',
     .                c2='/DFS/WAV_SHA',
     .                i2=mdet)
        ELSEIF (unused==2) THEN
          CALL ancmsg(msgid=102,msgtype=msgerror,anmode=aninfo,
     .                i1=det_id,
     .                c1='DETONATOR MUST REFER TO A JWL MATERIAL LAW (LAWS 5, 51, 97, 151)',
     .                c2='/DFS/WAV_SHA',
     .                i2=mdet)
        ELSE
          !---------------------------------!
          !        LISTING PRINTOUT         !
          !---------------------------------!
          npe = nodgrnr5(igu ,igs,iecran(1),igrnod ,itabm1 ,mess)
          !Nodes in group are ordered from 1 to NPE. last point is the nearest from the detonation origin. Points are composing the screen lines (guard lines). Screen lines is the boundary of the obstacle (shadow area
          IF(is_encrypted) WRITE(iout,1001)
          IF(.NOT.is_encrypted)WRITE(iout,1550) det_id,vdet,yc1,zc1,alt,mdet,igu,npe
          IF(.NOT.is_encrypted)WRITE(iout,fmt=fmw_10i) (itab(iecran(i)),i=1,npe)
          DO i=1,npe
            CALL ifrontplus(iecran(i),1)
          END DO
          detonators%WAVE_SHAPER(idet)%TDET = alt
          detonators%WAVE_SHAPER(idet)%MAT = mat
          detonators%WAVE_SHAPER(idet)%VDET = vdet
          detonators%WAVE_SHAPER(idet)%XDET = zero
          detonators%WAVE_SHAPER(idet)%YDET = yc1
          detonators%WAVE_SHAPER(idet)%ZDET = zc1
          detonators%WAVE_SHAPER(idet)%NUMNOD = npe
        END IF
 
      ENDDO !next IDET
C-----------------------------------------------
C   O u t p u t   F o r m a t
C-----------------------------------------------
 1001 FORMAT(///5x,
     &          'SHADOW LINE DETONATION    ',i10,/5x,
     &          '----------------------    ',/5x,
     &          'CONFIDENTIAL DATA')    
 1550 FORMAT(///5x,
     &          'SHADOW LINE DETONATION    =',i10,/5x,
     &          '----------------------     ',/5x,
     &          'OPTIONAL VELOCITY         =',1pg20.13,/5x,
     &          'Y-COORDINATE              =',1pg20.13,/5x,
     &          'Z-COORDINATE              =',1pg20.13,/5x,
     &          'LIGHTING TIME             =',1pg20.13,/5x,
     &          'explosive material number =',I10,/5X,
     &          'shadow line node group id =',I10,/5X,
     &          'number of points(shadow)  =',I10,/5X,
     &          'shadow line definition :   ')
 
C-----------------------------------------------
      END SUBROUTINE