read_sensor_nic.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_sensor_nic        ../starter/source/tools/sensor/read_sensor_nic.F
!||--- called by ------------------------------------------------------
!||    hm_read_sensors        ../starter/source/tools/sensor/hm_read_sensors.F
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_get_string          ../starter/source/devtools/hm_reader/hm_get_string.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE read_sensor_nic(
     .           SENSOR_PTR,SENS_ID  ,TITR     ,ISKN     ,
     .           UNITAB   ,LSUBMODEL )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------  
      USE unitab_mod
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE sensor_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "tabsiz_c.inc"
#include      "com04_c.inc"
#include      "sphcom.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: SENS_ID
      INTEGER ,DIMENSION(LISKN,SISKWN) ,INTENT(IN)  :: ISKN
      CHARACTER(LEN=NCHARTITLE)                :: TITR
      TYPE (SENSOR_STR_)   ,INTENT(OUT)        :: SENSOR_PTR
      TYPE (SUBMODEL_DATA) ,DIMENSION(NSUBMOD) :: LSUBMODEL
      TYPE (SUBSET_)       ,DIMENSION(NSUBS)   :: SUBSET
      TYPE (UNIT_TYPE_)    ,INTENT(IN) :: UNITAB 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,SENS_TYPE,SPRING_ID,SKEW_ID,ISK,NPOINT,IDIR1,IDIR2,
     .   NPARIS,NPARRS,NVAR
      my_real :: tdel,tmin,nijmax,ftens,fcomp,mflex,mext,alpha,cfc,
     .           fac_forc,fac_mom
      CHARACTER(LEN=NCHARFIELD) :: F_DIR, M_DIR
      LOGICAL :: IS_AVAILABLE
c--------------------------------
c     SENSOR BASED ON NECK INJURY CRITERION FOR SAFETY
c=======================================================================
      is_available = .false.
      sens_type    = 19
      idir1 = 0
      idir2 = 0
c--------------------------------------------------
card1
      CALL hm_get_floatv('Tdelay'    ,tdel     ,is_available,lsubmodel,unitab)
card2
      CALL hm_get_floatv('NIJ_max'   ,nijmax    ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Fint_tens' ,ftens     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Fint_comp' ,fcomp     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Mint_flex' ,mflex     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Mint_ext'  ,mext      ,is_available,lsubmodel,unitab)
card3
      CALL hm_get_intv  ('Spring_Id' ,spring_id ,is_available,lsubmodel)
      CALL hm_get_intv  ('Skew_Id'   ,skew_id   ,is_available,lsubmodel)
      CALL hm_get_string('Ax_Dir'    ,f_dir       ,ncharfield,is_available)
      CALL hm_get_string('Bend_Dir'  ,m_dir      ,ncharfield,is_available)
card4
      CALL hm_get_floatv('Tmin'      ,tmin      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Alpha'     ,alpha     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('CFC'       ,cfc       ,is_available,lsubmodel,unitab)
c
c--------------------------------------------------
c     Check input and default values
c--------------------------------------------------
      IF (f_dir(1:1) == 'X' .or. f_dir(1:1) == 'x') idir1 = 1
      IF (f_dir(1:1) == 'Y' .or. f_dir(1:1) == 'y') idir1 = 2
      IF (f_dir(1:1) == 'Z' .or. f_dir(1:1) == 'z') idir1 = 3
      IF (m_dir(1:1) == 'X' .or. m_dir(1:1) == 'x') idir2 = 1
      IF (m_dir(1:1) == 'Y' .or. m_dir(1:1) == 'y') idir2 = 2
      IF (m_dir(1:1) == 'Z' .or. m_dir(1:1) == 'z') idir2 = 3
      IF (idir1 == 0) THEN
        idir1 = 3
        f_dir = 'Z'
      END IF
      IF (idir2 == 0) THEN
        idir1 = 2
        m_dir  = 'Y'
      END IF
c
      isk = 0
      IF (skew_id > 0) THEN      
        DO i = 0,numskw+min(1,nspcond)*numsph+nsubmod
          IF (skew_id == iskn(4,i+1)) THEN
            isk = i+1
            EXIT
          ENDIF
        ENDDO
      END IF
      fac_forc = unitab%FAC_M_WORK * unitab%FAC_L_WORK / unitab%FAC_T_WORK**2
      fac_mom  = fac_forc * unitab%FAC_L_WORK
      IF (ftens == 0) ftens = 6806.0 / fac_forc 
      IF (fcomp == 0) fcomp = 6160.0 / fac_forc 
      IF (mflex == 0) mflex = 310.0  / fac_mom
      IF (mext  == 0) mext  = 135.0  / fac_mom
      IF (alpha == 0) alpha = 2.0775
      IF (cfc == zero) cfc  = 600.0 * unitab%FAC_T_WORK
c--------------------------------------------------
c     sensor data structure
c--------------------------------------------------
      npoint = 5      
      nparis = 6             ! int  value parameters
      nparrs = 7             ! real value parameters
      nvar   = npoint*4 + 5  ! internal variables
c
      ALLOCATE (sensor_ptr%IPARAM(nparis))
      ALLOCATE (sensor_ptr%RPARAM(nparrs))
      ALLOCATE (sensor_ptr%VAR(nvar))
      sensor_ptr%VAR(:) = zero
 
      sensor_ptr%NVAR    = nvar
      sensor_ptr%NPARI   = nparis
      sensor_ptr%NPARR   = nparrs
      sensor_ptr%TYPE    = sens_type
      sensor_ptr%SENS_ID = sens_id
      sensor_ptr%STATUS  = 0          ! status = initially deactivated
      sensor_ptr%TSTART  = infinity   ! start time
      sensor_ptr%TCRIT   = infinity   ! global activation time
      sensor_ptr%TDELAY  = tdel       ! time delay before activation
      sensor_ptr%TMIN    = tmin       ! min time duration to validate criterion
      sensor_ptr%VALUE   = zero
c
      sensor_ptr%IPARAM(1) = spring_id
      sensor_ptr%IPARAM(2) = 0        ! spring number - initialized in inisens()
      sensor_ptr%IPARAM(3) = isk
      sensor_ptr%IPARAM(4) = 0        ! spring skew   - initialized in inisens()
      sensor_ptr%IPARAM(5) = idir1
      sensor_ptr%IPARAM(6) = idir2
c
      sensor_ptr%RPARAM(1) = nijmax
      sensor_ptr%RPARAM(2) = ftens
      sensor_ptr%RPARAM(3) = fcomp
      sensor_ptr%RPARAM(4) = mflex
      sensor_ptr%RPARAM(5) = mext
      sensor_ptr%RPARAM(6) = alpha
      sensor_ptr%RPARAM(7) = cfc   
c------------------------------------------------------------
      WRITE (iout ,1000) sens_id,tdel,tmin
      WRITE (iout ,2000) nijmax,ftens,fcomp,mflex,mext,spring_id,skew_id,
     .                   f_dir,m_dir,cfc,alpha
c------------------------------------------------------------
 1000 FORMAT(
     . 5x,'    SENSOR : NECK INJURY CRITERION          '/,
     . 5x,'    ------------------------------          '/,
     . 5x,'SENSOR ID. . . . . . . . . . . . . . . . . =',i10/
     . 5x,'TIME DELAY BEFORE ACTIVATION . . . . . . . =',e12.4/
     . 5x,'MINIMUM TIME DURATION. . . . . . . . . . . =',e12.4)
 2000 FORMAT(
     . 5x,'  NIJ LIMIT VALUE. . . . . . . . . . . . . =',e12.4/
     . 5x,'  CRITICAL AXIAL FORCE IN TENSION. . . . . =',e12.4/
     . 5x,'  CRITICAL AXIAL FORCE IN COMPRESSION. . . =',e12.4/
     . 5x,'  CRITICAL BENDING MOMENT IN FLEXION . . . =',e12.4/
     . 5x,'  CRITICAL BENDING MOMENT IN EXTENSION . . =',e12.4/
     . 5x,'  SPRING ELEMENT ID. . . . . . . . . . . . =',i10/
     . 5x,'  LOCAL SKEW SYSTEM ID . . . . . . . . . . =',i10/
     . 5x,'  DIRECTION OF AXIAL FORCE MONITORING. . . =',9x,a1/
     . 5x,'  DIRECTION OF BENDING MOMENT MONITORING . =',9x,a1/
     . 5x,'  CFC - CHANNEL FREQUENCY CLASS. . . . . . =',e12.4/
     . 5x,'  FILTER CONSTANT. . . . . . . . . . . . . =',e12.4/)
c-----------
      RETURN
      END