rotloc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rotloc   ../engine/source/materials/mat/mat024/rotloc.F
!||--- called by ------------------------------------------------------
!||    conc24   ../engine/source/materials/mat/mat024/conc24.F
!||====================================================================
      SUBROUTINE rotloc(
     1   NEL,     GAMA,    RX,      RY,
     2   RZ,      SX,      SY,      SZ,
     3   R11,     R12,     R13,     R21,
     4   R22,     R23,     R31,     R32,
     5   R33,     JCVT,    JSPH)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JCVT
      INTEGER, INTENT(IN) :: JSPH
      INTEGER NEL
      my_real, DIMENSION(NEL), INTENT(INOUT)  :: RX,RY,RZ,SX,SY,SZ
      my_real, DIMENSION(NEL), INTENT(OUT)    :: R11,R12,R13,R21,R22,
     .                                           r23,r31,r32,r33
      my_real, DIMENSION(MVSIZ,6) :: gama
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real RR
      my_real, DIMENSION(NEL) :: S11,S12,S13,S21,S22,S23,S31,S32,S33,
     .   TX,TY,TZ
C=======================================================================
      IF (jsph==0) THEN
        IF (jcvt==0) THEN
          IF(n2d==0)THEN
            DO i = 1,nel
            rr   =sqrt(rx(i)**2+ry(i)**2+rz(i)**2)
            rx(i)=rx(i)/rr
            ry(i)=ry(i)/rr
            rz(i)=rz(i)/rr
            ENDDO
            DO i = 1,nel
            tx(i)=ry(i)*sz(i)-rz(i)*sy(i)
            ty(i)=rz(i)*sx(i)-rx(i)*sz(i)
            tz(i)=rx(i)*sy(i)-ry(i)*sx(i)
            rr   =sqrt(tx(i)**2+ty(i)**2+tz(i)**2)
            tx(i)=tx(i)/rr
            ty(i)=ty(i)/rr
            tz(i)=tz(i)/rr
            ENDDO
            DO i = 1,nel
            sx(i)=ty(i)*rz(i)-tz(i)*ry(i)
            sy(i)=tz(i)*rx(i)-tx(i)*rz(i)
            sz(i)=tx(i)*ry(i)-ty(i)*rx(i)
            rr   =sqrt(sx(i)**2+sy(i)**2+sz(i)**2)
            sx(i)=sx(i)/rr
            sy(i)=sy(i)/rr
            sz(i)=sz(i)/rr
            ENDDO
          ELSE
C---------------------------------------------
C            in 2d the stresses are:
C            1=YY 2=ZZ 3=TT 4=YZ 5=0 6=0
C            CONTRADICTION WITH X=T
C---------------------------------------------
            DO i = 1,nel
            rr   = sqrt(sy(i)**2+sz(i)**2)
            rx(i)= sy(i)/rr
            ry(i)= sz(i)/rr
            rz(i)= zero
            sx(i)=-ry(i)
            sy(i)= rx(i)
            sz(i)= zero
            tx(i)= zero
            ty(i)= zero
            tz(i)= one    
            ENDDO
          ENDIF
C
          DO i = 1,nel
          s11(i)=gama(i,1)
          s21(i)=gama(i,2)
          s31(i)=gama(i,3)
          s12(i)=gama(i,4)
          s22(i)=gama(i,5)
          s32(i)=gama(i,6)
          s13(i)=s21(i)*s32(i)-s31(i)*s22(i)
          s23(i)=s31(i)*s12(i)-s11(i)*s32(i)
          s33(i)=s11(i)*s22(i)-s21(i)*s12(i)
          ENDDO
C
          DO i = 1,nel
          r11(i) = s11(i)*rx(i)+s21(i)*sx(i)+s31(i)*tx(i)
          r21(i) = s11(i)*ry(i)+s21(i)*sy(i)+s31(i)*ty(i)
          r31(i) = s11(i)*rz(i)+s21(i)*sz(i)+s31(i)*tz(i)
C
          r12(i) = s12(i)*rx(i)+s22(i)*sx(i)+s32(i)*tx(i)
          r22(i) = s12(i)*ry(i)+s22(i)*sy(i)+s32(i)*ty(i)
          r32(i) = s12(i)*rz(i)+s22(i)*sz(i)+s32(i)*tz(i)
C
          r13(i) = s13(i)*rx(i)+s23(i)*sx(i)+s33(i)*tx(i)
          r23(i) = s13(i)*ry(i)+s23(i)*sy(i)+s33(i)*ty(i)
          r33(i) = s13(i)*rz(i)+s23(i)*sz(i)+s33(i)*tz(i)
          ENDDO
c-------------------------------------------------------
        ELSE
c         CO-ROTATIONAL FORMULATION IN ORTHOTROPIC CO-ROTATIONAL SYSTEM.
          DO i = 1,nel
           r11(i) = one
           r21(i) = zero
           r31(i) = zero
C
           r12(i) = zero
           r22(i) = one
           r32(i) = zero
C
           r13(i) = zero
           r23(i) = zero
           r33(i) = one
          ENDDO
        ENDIF
C-------------------------------------------------------
      ELSE
        DO i = 1,nel
         r11(i)=gama(i,1)
         r21(i)=gama(i,2)
         r31(i)=gama(i,3)
         r12(i)=gama(i,4)
         r22(i)=gama(i,5)
         r32(i)=gama(i,6)
         r13(i)=r21(i)*r32(i)-r31(i)*r22(i)
         r23(i)=r31(i)*r12(i)-r11(i)*r32(i)
         r33(i)=r11(i)*r22(i)-r21(i)*r12(i)
        ENDDO
      ENDIF
c-----------
      RETURN
      END