sensor_dist_surf0.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "com04_c.inc"
#include "com01_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sensor_dist_surf0 (nsensor, sensor_tab, x, igrsurf, comm_sens16)

Function/Subroutine Documentation

sensor_dist_surf0()

subroutine sensor_dist_surf0	(	integer, intent(in)	nsensor,
		type (sensor_str_), dimension(nsensor), intent(inout)	sensor_tab,
		dimension(3,numnod)	x,
		type (surf_), dimension(nsurf), target	igrsurf,
		type (sensor_comm), intent(in)	comm_sens16 )

Definition at line 35 of file sensor_dist_surf0.F.

!$COMMENT
!       sensor_dist_surf0 description
!       computation of distance to surface for sensor typ16
!       and reduction with a mpi communication
!       
!       SENSOR_DIST_SURF0 organization :
!       - computation of local distance
!       - reduction with mpi comm
!$ENDCOMMENT
c-----------------------------------------------
C   M o d u l e s
c-----------------------------------------------
      USE spmd_mod
      USE groupdef_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NSENSOR
      my_real ,DIMENSION(3,NUMNOD) :: x
      TYPE (SURF_) ,DIMENSION(NSURF), TARGET :: IGRSURF
      TYPE (SENSOR_STR_), DIMENSION(NSENSOR),INTENT(INOUT) :: SENSOR_TAB
      TYPE (SENSOR_COMM), INTENT(IN) :: COMM_SENS16
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
       INTEGER I,ISURF,INOD,NP1,NP2,NP3,NP4,NSEG,IJK
       my_real dist,dmin,dmax,alpha,tmin,tdelay
       my_real xnod,ynod,znod,xp1,yp1,zp1,xp2,yp2,zp2,xp3,yp3,zp3,
     .    xp4,yp4,zp4,norm,infinity
      TYPE (SURF_) ,POINTER :: SURFACE
      parameter(infinity = 1.0e20)
      INTEGER :: ISENS
      my_real, DIMENSION(COMM_SENS16%NUM_SENS) :: local_value,global_value
!     -----------------------------------------------------------
 
      ! -----------------
      ! computation of local distance (one distance per processor)
      DO ijk=1,comm_sens16%NUM_SENS
        isens = comm_sens16%ID_SENS(ijk)
        local_value(ijk) = zero
        global_value(ijk) = zero
        IF (sensor_tab(isens)%STATUS == 1) cycle   ! already activated
 
C.....................................................
C ==> DIST between node and a plan defined by 3 nodes
C.....................................................
C     ID_N1 : Node identifier
C     ID_PN1 : Plan Node 1 identifier
C     ID_PN2 : Plan Node 2 identifier
C     ID_PN3 : Plan Node 3 identifier
C
        tmin   = sensor_tab(isens)%TMIN        ! min criterion time duration
        tdelay = sensor_tab(isens)%TDELAY      ! time delay before activation
        inod   = sensor_tab(isens)%IPARAM(1)
        isurf  = sensor_tab(isens)%IPARAM(2)
c
        dmin   = sensor_tab(isens)%RPARAM(1)
        dmax   = sensor_tab(isens)%RPARAM(2)
c
c...  Current position of reference node
c
        xnod  = x(1,inod)
        ynod  = x(2,inod)
        znod  = x(3,inod)
c    
c
      ! calculate distance to Surf_Id composed of segments
c
        surface => igrsurf(isurf)
        nseg = surface%NSEG
c--------------------
        SELECT CASE (surface%TYPE)
c--------------------
          CASE (2)  ! SOLIDS
c
c           to be completed
c
          CASE (3)  ! SH4N
c
            DO i = 1,nseg
              np1 = surface%NODES(i,1)
              np2 = surface%NODES(i,2)
              np3 = surface%NODES(i,3)
              np4 = surface%NODES(i,4)
              xp1 = x(1,np1)
              yp1 = x(2,np1)
              zp1 = x(3,np1)
              xp2 = x(1,np2)
              yp2 = x(2,np2)
              zp2 = x(3,np2)
              xp3 = x(1,np3)
              yp3 = x(2,np3)
              zp3 = x(3,np3)
              xp4 = x(1,np4)
              yp4 = x(2,np4)
              zp4 = x(3,np4)
              CALL dist_node_seg4n(
     .             dist,dmin,dmax,xnod,ynod,znod, 
     .             xp1,yp1,zp1,xp2,yp2,zp2,xp3,yp3,zp3,xp4,yp4,zp4)
              sensor_tab(isens)%VALUE = min(sensor_tab(isens)%VALUE, dist)
            END DO            
c
          CASE (7)  ! SH3N          
c
            DO i = 1,nseg
              np1 = surface%NODES(i,1)
              np2 = surface%NODES(i,2)
              np3 = surface%NODES(i,3)
              xp1 = x(1,np1)
              yp1 = x(2,np1)
              zp1 = x(3,np1)
              xp2 = x(1,np2)
              yp2 = x(2,np2)
              zp2 = x(3,np2)
              xp3 = x(1,np3)
              yp3 = x(2,np3)
              zp3 = x(3,np3)
c
              CALL dist_node_seg3n(
     .             dist,dmin,dmax,xnod,ynod,znod, 
     .             xp1,yp1,zp1,xp2,yp2,zp2,xp3,yp3,zp3)
              sensor_tab(isens)%VALUE = min(sensor_tab(isens)%VALUE, dist)
            END DO            
c
c--------------------
        END SELECT
c--------------------
        local_value(ijk) = sensor_tab(isens)%VALUE
      ENDDO
      ! -----------------
      ! reduction with mpi comm
      IF(nspmd>1) THEN
        CALL spmd_allreduce(local_value,global_value,comm_sens16%NUM_SENS,spmd_min)
      ELSE
        global_value(1:comm_sens16%NUM_SENS) = local_value(1:comm_sens16%NUM_SENS)
      ENDIF
      DO ijk=1,comm_sens16%NUM_SENS
        isens = comm_sens16%ID_SENS(ijk)
        sensor_tab(isens)%VALUE = global_value(ijk)
      ENDDO
      ! -----------------
 
      RETURN