sensor_nic.F File Reference

#include "implicit_f.inc"
#include "comlock.inc"
#include "units_c.inc"
#include "com08_c.inc"
#include "task_c.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sensor_nic (sensor)

Function/Subroutine Documentation

sensor_nic()

subroutine sensor_nic

(

type (sensor_str_)

sensor

)

Definition at line 32 of file sensor_nic.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (SENSOR_STR_) :: SENSOR
C----------------------------------------------------------
C Local Variables
C----------------------------------------------------------
      INTEGER NPT,NPH,IADFX,IADFY,IADMX,IADMY,ICRIT
      my_real :: for,mom,dt,time,nijmax,nic,alpha,beta,cfc,tmin,tdelay,
     .   wd,wa,wa2,wa3,a0,a1,a2,b1,b2,x0,x1,x2,y1,y2,yf,ym,infinity
      parameter(infinity = 1.0e20)
c-----------------------------------------------------------------------
c     Sensor state variables
c        SENSOR%VAR(1) :  Current non filtered spring force
c        SENSOR%VAR(2) :  Current non filtered spring moment
c        SENSOR%VAR(3) :  flag spmd : =0 => spring not present in the domain
c                                     =1 => spring is present in the domain
c        free
c        SENSOR%VAR(6 -10)  :  non filtered force values 
c        SENSOR%VAR(11-15)  :  filtered force values    
c        SENSOR%VAR(16-20   :  non filtered moment values 
c        SENSOR%VAR(21-25)  :  filtered moment values 
C=======================================================================
      IF (sensor%STATUS == 1)    RETURN   ! already activated
      IF (sensor%VAR(3) == zero) RETURN   ! spring is on different spmd domain
c
      tmin   = sensor%TMIN
      tdelay = sensor%TDELAY
      nijmax = sensor%RPARAM(1)
      alpha  = sensor%RPARAM(6)
      cfc    = sensor%RPARAM(7)
      time   = tt
      icrit  = 0
c
c     Parameters of SAE-J211 CFC filter
      dt   = dt2    
      wd   = two*pi*cfc*alpha
      beta = half * dt * wd
      wa   = tan(beta)
      wa2  = wa**2
      wa3  = one + sqr2*wa + wa2
      a0   = wa2 / wa3
      a1   = a0 * two
      a2   = a0
      b1   = -two*(wa2 - one) / wa3
      b2   = (-one + sqr2*wa - wa2) / wa3
c
c     current non filtered normalized spring force and moment
      for  = sensor%VAR(1)
      mom  = sensor%VAR(2)
c
      npt = 5
      nph = 3
      iadfx = 5
      iadfy = iadfx + npt
      iadmx = iadfy + npt
      iadmy = iadmx + npt
c
      ! forward filter - forces
c
      x0 = for
      x1 = sensor%VAR(iadfx+5)      
      x2 = sensor%VAR(iadfx+4)    
      y1 = sensor%VAR(iadfy+5)  
      y2 = sensor%VAR(iadfy+4)
c      
      yf = a0*x0 + a1*x1 + a2*x2 + b1*y1 + b2*y2
c              
      sensor%VAR(iadfx+1) = sensor%VAR(iadfx+2)
      sensor%VAR(iadfx+2) = sensor%VAR(iadfx+3)
      sensor%VAR(iadfx+3) = sensor%VAR(iadfx+4)
      sensor%VAR(iadfx+4) = sensor%VAR(iadfx+5)  
      sensor%VAR(iadfx+5) = for
c
      sensor%VAR(iadfy+1) = sensor%VAR(iadfy+2)
      sensor%VAR(iadfy+2) = sensor%VAR(iadfy+3)
      sensor%VAR(iadfy+3) = sensor%VAR(iadfy+4)
      sensor%VAR(iadfy+4) = sensor%VAR(iadfy+5)  
      sensor%VAR(iadfy+5) = yf
c
      ! backward filter - forces
c
      x0 = sensor%VAR(iadfx+nph)
      x1 = sensor%VAR(iadfx+nph+1)
      x2 = sensor%VAR(iadfx+nph+2)
      y1 = sensor%VAR(iadfy+nph+1)
      y2 = sensor%VAR(iadfy+nph+2)
c      
      for = a0*x0 + a1*x1 + a2*x2 + b1*y1 + b2*y2
c
      ! forward filter - moments
      x0 = mom
      x1 = sensor%VAR(iadmx+5)      
      x2 = sensor%VAR(iadmx+4)
      y1 = sensor%VAR(iadmy+5)
      y2 = sensor%VAR(iadmy+4)
c      
      ym = a0*x0 + a1*x1 + a2*x2 + b1*y1 + b2*y2
c              
      sensor%VAR(iadmx+1) = sensor%VAR(iadmx+2)
      sensor%VAR(iadmx+2) = sensor%VAR(iadmx+3)
      sensor%VAR(iadmx+3) = sensor%VAR(iadmx+4)
      sensor%VAR(iadmx+4) = sensor%VAR(iadmx+5)  
      sensor%VAR(iadmx+5) = mom
      
      sensor%VAR(iadmy+1) = sensor%VAR(iadmy+2)
      sensor%VAR(iadmy+2) = sensor%VAR(iadmy+3)
      sensor%VAR(iadmy+3) = sensor%VAR(iadmy+4)
      sensor%VAR(iadmy+4) = sensor%VAR(iadmy+5)  
      sensor%VAR(iadmy+5) = ym
c
      ! backward filter - moments
c      
      x0  = sensor%VAR(iadmx+nph)
      x1  = sensor%VAR(iadmx+nph+1)
      x2  = sensor%VAR(iadmx+nph+2)
      y1  = sensor%VAR(iadmy+nph+1)
      y2  = sensor%VAR(iadmy+nph+2)
      mom = a0*x0 + a1*x1 + a2*x2 + b1*y1 + b2*y2               
c
      nic = for + mom
      IF (nic >= nijmax) icrit = 1
c-----------------------------------------
c     Check Sensor State
c-----------------------------------------
      IF (sensor%TCRIT + tmin > tt) THEN
        IF (icrit == 0) THEN
          sensor%TCRIT = infinity
        ELSE IF (sensor%TCRIT == infinity) THEN
          sensor%TCRIT = min(sensor%TCRIT, tt)
        END IF
      ELSE IF (sensor%TSTART == infinity) THEN
        sensor%TSTART = sensor%TCRIT + tmin + tdelay
      END IF
      IF (sensor%TSTART <= tt) THEN   ! sensor activation
        sensor%STATUS = 1
      END IF
c-----------------------------------------------------------------------      
      IF (sensor%STATUS == 1 .and. ispmd == 0) THEN
#include "lockon.inc"
        WRITE (istdo,1100 ) sensor%SENS_ID,sensor%TSTART,nic
        WRITE (iout ,1100 ) sensor%SENS_ID,sensor%TSTART,nic
        WRITE (iout ,1200) nijmax,nic
#include "lockoff.inc"
      ENDIF
c-----------------------------------------------------------------------      
1100  FORMAT(' SENSOR (RBODY) NUMBER ',i10,' ,ACTIVATED AT TIME ',1pe12.5)
1200  FORMAT('      TARGET NIC VALUE = ',1pe12.5,/
     .       '      CURRENT NIC VALUE AFTER TMIN and TDELAY = ',1pe12.5)
c-----------------------------------------------------------------------      
      RETURN