sigaboyce.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sigaboyce (nel, matb, c1, c2, c3, c4, c5, mu, beta, d, sig, bi1, jdet, flag_mul, nvarf, coefr, betaf, coefm, uvarf)

Function/Subroutine Documentation

sigaboyce()

subroutine sigaboyce	(	integer, intent(in)	nel,
		intent(in)	matb,
		intent(in)	c1,
		intent(in)	c2,
		intent(in)	c3,
		intent(in)	c4,
		intent(in)	c5,
		intent(in)	mu,
		intent(in)	beta,
		intent(in)	d,
		dimension(nel, 3,3)	sig,
		intent(out)	bi1,
		intent(out)	jdet,
		integer, intent(in)	flag_mul,
		integer, intent(in)	nvarf,
		intent(in)	coefr,
		intent(in)	betaf,
		intent(in)	coefm,
		intent(inout)	uvarf )

Definition at line 33 of file sigaboyce.F.

C-----------------------------------------------
C   I M P L I C I T   T Y P E S
C-----------------------------------------------
#include "implicit_f.inc"
C----------------------------------------------------------------
C  I N P U T   A R G U M E N T S
C----------------------------------------------------------------
      INTEGER,  INTENT(IN) ::       NEL,FLAG_MUL,NVARF
      my_real,  INTENT(IN) :: c1,c2,c3,c4,c5,mu,beta,d ,
     .                        coefr, betaf,coefm          
      my_real, DIMENSION(NEL, 3,3) , INTENT(IN) ::  matb 
C----------------------------------------------------------------
C  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real, DIMENSION(NEL), INTENT(OUT) :: bi1 ,jdet 
      my_real, DIMENSION(NEL, 3,3)  :: sig  
C----------------------------------------------------------------
C  I N P U T  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real, DIMENSION(NEL,NVARF), INTENT(INOUT) :: uvarf
C----------------------------------------------------------------
C  L O C A L  V A R I B L E S
C----------------------------------------------------------------
      INTEGER    I
 
      my_real     
     .   j2third(nel),i1(nel),jthird(nel),ww(nel),
     .   dphidi1(nel) ,dphidj(nel) ,eta(nel)
C----------------------------------------------------------------
      eta(1:nel) = one !MULLINS DAMAGE FACTOR
      DO i = 1,nel
         jdet(i)=matb(i,1,1)*matb(i,2,2)*matb(i,3,3) -matb(i,1,1)*matb(i,2,3)*matb(i,3,2) -
     .       matb(i,3,3)*matb(i,1,2)*matb(i,2,1) +matb(i,1,2)*matb(i,2,3)*matb(i,3,1) +
     .       matb(i,2,1)*matb(i,3,2)*matb(i,1,3) -matb(i,2,2)*matb(i,3,1)*matb(i,1,3)
         jdet(i)= sqrt(max(em20, jdet(i)))    
        !INVARIANT BAR         
         i1(i) = matb(i,1,1)+matb(i,2,2)+matb(i,3,3)
         IF(jdet(i)>zero) THEN
          jthird(i)  = exp((-third )*log(jdet(i)))
          j2third(i) = jthird(i)**2       
         ELSE
          jthird(i)  = zero
          j2third(i) = zero
         ENDIF
        !first invariant deviator BI1:
         bi1(i) = i1(i) * j2third(i) 
      ENDDO
      !====================================
      !dammge by mullins effect
      !====================================
      IF(flag_mul == 1)THEN
       DO i = 1,nel
         ww(i) =  mu *( c1 * (bi1(i)- three)+c2 * beta *   (bi1(i)**2- nine)
     .   +                                   c3 * beta**2 *(bi1(i)**3- three**3)    
     .   +                                   c4 * beta**3 *(bi1(i)**4- three**4)
     .   +                                   c5 * beta**4 *(bi1(i)**5- three**5) )
 
       ENDDO
       CALL mullins_or(
     1                nel ,nvarf, coefr,betaf ,
     2                coefm, ww  , uvarf,eta )
 
      ENDIF
      !====================================
 
      DO i = 1,nel
        eta(i) = max(min(eta(i),one),em20)
        dphidi1(i) = eta(i)* two*mu *( c1 + two * c2 * beta * bi1(i)
     .   +                           three* c3 *(beta *bi1(i))**2    
     .   +                          four* c4 *(beta *bi1(i))**3 
     .   +                          five  * c5 *(beta *bi1(i))**4)/max(em20,jdet(i))
 
        dphidj(i)  = d * (  jdet(i) - one /max(em20,jdet(i)) ) !d=1/d
      ENDDO
      DO i = 1,nel
         sig(i,1,1) =  dphidi1(i)* (matb(i,1,1)-third*bi1(i))
     .       +   dphidj(i)        
         sig(i,2,2) =  dphidi1(i)* (matb(i,2,2)-third*bi1(i))
     .       +   dphidj(i)        
         sig(i,3,3) =  dphidi1(i)* (matb(i,3,3)-third*bi1(i))
     .       +   dphidj(i)        
         sig(i,1,2) =  dphidi1(i)*matb(i,1,2)
         sig(i,2,3) =  dphidi1(i)*matb(i,2,3)
         sig(i,3,1) =  dphidi1(i)*matb(i,3,1)
         sig(i,2,1)=sig(i,1,2)   
         sig(i,3,2)=sig(i,2,3)   
         sig(i,1,3)=sig(i,3,1)   
      ENDDO
 
      RETURN