sigeps34c.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sigeps34c (nel, nuparam, nuvar, nfunc, ifunc, npf, tf, time, timestep, uparam, rho0, thkly, gs, epspxx, epspyy, epspxy, epspyz, epspzx, depsxx, depsyy, depsxy, depsyz, depszx, epsxx, epsyy, epsxy, epsyz, epszx, sigoxx, sigoyy, sigoxy, sigoyz, sigozx, signxx, signyy, signxy, signyz, signzx, soundsp, thk, uvar, off)

Function/Subroutine Documentation

sigeps34c()

subroutine sigeps34c	(	integer	nel,
		integer	nuparam,
		integer	nuvar,
		integer	nfunc,
		integer, dimension(nfunc)	ifunc,
		integer, dimension(*)	npf,
			tf,
			time,
			timestep,
			uparam,
		dimension(nel)	rho0,
		dimension(nel)	thkly,
		dimension(nel)	gs,
		dimension(nel)	epspxx,
		dimension(nel)	epspyy,
		dimension(nel)	epspxy,
		dimension(nel)	epspyz,
		dimension(nel)	epspzx,
		dimension(nel)	depsxx,
		dimension(nel)	depsyy,
		dimension(nel)	depsxy,
		dimension(nel)	depsyz,
		dimension(nel)	depszx,
		dimension(nel)	epsxx,
		dimension(nel)	epsyy,
		dimension(nel)	epsxy,
		dimension(nel)	epsyz,
		dimension(nel)	epszx,
		dimension(nel)	sigoxx,
		dimension(nel)	sigoyy,
		dimension(nel)	sigoxy,
		dimension(nel)	sigoyz,
		dimension(nel)	sigozx,
		intent(out)	signxx,
		intent(out)	signyy,
		intent(out)	signxy,
		intent(out)	signyz,
		intent(out)	signzx,
		intent(out)	soundsp,
		dimension(nel)	thk,
			uvar,
			off )

Definition at line 30 of file sigeps34c.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C----------------------------------------------------------------
C  I N P U T   A R G U M E N T S
C----------------------------------------------------------------
      INTEGER  :: NEL,NUPARAM, NUVAR
      my_real :: time,timestep
      my_real :: uparam(nuparam)
      my_real ,DIMENSION(NEL) ::
     .      rho0  , 
     .      epspxx, epspyy,epspxy, epspyz, epspzx,
     .      depsxx, depsyy, depsxy, depsyz, depszx,
     .      epsxx , epsyy , epsxy , epsyz , epszx,
     .      sigoxx, sigoyy,sigoxy, sigoyz, sigozx,
     .      gs    ,thkly ,    thk
C----------------------------------------------------------------
C  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real ,DIMENSION(NEL) ,INTENT(OUT) :: soundsp,
     .    signxx,signyy,signxy,signyz,signzx
C----------------------------------------------------------------
C  I N P U T  O U T P U T   A R G U M E N T S
C----------------------------------------------------------------
      my_real :: uvar(nel,nuvar), off(nel) 
C----------------------------------------------------------------
C  VARIABLES FOR FUNCTION INTERPOLATION 
C----------------------------------------------------------------
      INTEGER NPF(*), NFUNC, IFUNC(NFUNC)
      my_real
     .        finter,tf(*)
      EXTERNAL finter
C----------------------------------------------------------------
C  L O C A L  V A R I B L E S
C----------------------------------------------------------------
C----------------------------------------------------------------
C  L O C A L  V A R I B L E S
C----------------------------------------------------------------
       INTEGER :: I, IFORM
       my_real :: bulk,bulk3,g_ins,g_inf,ge,ge2,gv,gv2,c1,c2,beta,
     .   aa, bb, dav, p, trace, h0(6),h(6),alpha,dp_drho,cc2
        my_real ,DIMENSION(NEL) :: 
     .   depsm,depszz, signzz, sigozz, depsdxx,depsdyy,depsdzz, dp,
     .   dexx,deyy,dezz,dexy,deyz,dezx,ddexx,ddeyy,ddezz,ddexy,ddeyz,
     .   ddezx,depsdxy,depsdyz,depsdzx,epspm,
     .   depsvxx,depsvyy,depsvzz,depsvxy,depsvyz,depsvzx,em,epsm ,epszz,
     .   epspzz 
C=======================================================================
          bulk  = uparam(1)     
          g_ins = uparam(2)        ! instant shear modulus
          g_inf = uparam(3)        ! long term shear modulus
          beta  = uparam(4)
c            
            ge  = g_inf              ! elastic part of shear modulus
            gv  = g_ins-g_inf        ! viscous part of shear modulus
            ge2 = ge * two
            gv2 = gv * two
            c1  = one - exp(-beta*timestep)
            c2  =-c1 / beta
            bulk3 = bulk*three
            cc2 = gv2*(c1 + c2/max(em20,timestep))
c
            DO i=1,nel
              !
              ! Computing depzz assuming signzz= 0
              !
               dezz(i) = uvar(i,7)
               h(3)   = uvar(i,3)
               aa = gv2*c1*(dezz(i) - h(3)) + third*(ge2 - cc2 - bulk3)*(depsxx(i) + depsyy(i)) 
               bb = two_third*ge2 + bulk - two_third*cc2
               depszz(i) = aa/bb  
               ddezz(i) = two_third*depszz(i) - third*(depsxx(i) + depsyy(i))
               dezz(i)  = uvar(i,7) + ddezz(i)
               epszz(i) = three_half*dezz(i) + half*(epsxx(i)+ epsyy(i))
               epspzz(i) = depszz(i)/max(em20,timestep)
               !!
               depsm(i) = third *(depsxx(i)+depsyy(i)+depszz(i))
               epspm(i) = third *(epspxx(i)+epspyy(i)+epspzz(i))
               em(i)    = third *(epsxx(i) +epsyy(i) +epszz(i) )
               uvar(i,7) = dezz(i)
              ! thickness 
               thk(i) = thk(i) + depszz(i)*thkly(i)*off(i)
            END DO
c
c           Deviators of strain, strain increment and strain rate       
c
            DO i=1,nel
              dexx(i) = epsxx(i)-em(i)
              deyy(i) = epsyy(i)-em(i)
              dezz(i) = epszz(i)-em(i)
              dexy(i) = epsxy(i)
              deyz(i) = epsyz(i)
              dezx(i) = epszx(i) 
c
              ddexx(i) = depsxx(i)-depsm(i)
              ddeyy(i) = depsyy(i)-depsm(i)
              ddezz(i) = depszz(i)-depsm(i)
              ddexy(i) = depsxy(i)
              ddeyz(i) = depsyz(i)
              ddezx(i) = depszx(i)
c
              depsdxx(i) = epspxx(i)-epspm(i)
              depsdyy(i) = epspyy(i)-epspm(i)
              depsdzz(i) = epspzz(i)-epspm(i)
              depsdxy(i) = epspxy(i)
              depsdyz(i) = epspyz(i)
              depsdzx(i) = epspzx(i)
            END DO
 
            DO i=1,nel
              depsvxx(i) = c1*(dexx(i)-uvar(i,1)) + c2*depsdxx(i)
              depsvyy(i) = c1*(deyy(i)-uvar(i,2)) + c2*depsdyy(i)
              depsvzz(i) = c1*(dezz(i)-uvar(i,3)) + c2*depsdzz(i)
              depsvxy(i) = c1*(dexy(i)-uvar(i,4)) + c2*depsdxy(i)
              depsvyz(i) = c1*(deyz(i)-uvar(i,5)) + c2*depsdyz(i)
              depsvzx(i) = c1*(dezx(i)-uvar(i,6)) + c2*depsdzx(i)
            END DO
 
            dp(1:nel) = bulk3  * depsm(1:nel)
 
            DO i=1,nel
              signxx(i) = sigoxx(i) + ge2*ddexx(i) - gv2*depsvxx(i) + dp(i)
              signyy(i) = sigoyy(i) + ge2*ddeyy(i) - gv2*depsvyy(i) + dp(i)
              !! SIGNZZ(I) =   GE2*DDEZZ(I) - GV2*DEPSVZZ(I) + DP(I) ! must be zero ! only for checking if is needed
              signxy(i) = sigoxy(i) + ge *ddexy(i) - gv *depsvxy(i)
              signyz(i) = sigoyz(i) + ge *ddeyz(i) - gv *depsvyz(i)
              signzx(i) = sigozx(i) + ge *ddezx(i) - gv *depsvzx(i)
            END DO        
c
            dp_drho = four_over_3*g_ins + bulk
            soundsp(1:nel) = sqrt(dp_drho / rho0(1:nel))
c
            DO i=1,nel
              uvar(i,1) = uvar(i,1) + depsvxx(i) + ddexx(i)
              uvar(i,2) = uvar(i,2) + depsvyy(i) + ddeyy(i)
              uvar(i,3) = uvar(i,3) + depsvzz(i) + ddezz(i)
              uvar(i,4) = uvar(i,4) + depsvxy(i) + ddexy(i)
              uvar(i,5) = uvar(i,5) + depsvyz(i) + ddeyz(i)
              uvar(i,6) = uvar(i,6) + depsvzx(i) + ddezx(i)
            END DO
C=======================================================================
 
c-----------        
      RETURN