spmd_check_ale_neighbour.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_check_ale_neighbour   ../engine/source/mpi/fluid/spmd_check_ale_neighbour.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod        ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
        SUBROUTINE spmd_check_ale_neighbour(ACTIVE_ELEMENT,NB_RCV_NEIGH,NB_SEND_NEIGH,
     .                                      INDEX_RCV_NEIGH,INDEX_SEND_NEIGH,LENCOM,
     .                                      TMP_NB_RCV_NEIGH,TMP_NB_SEND_NEIGH,
     .                                      TMP_INDEX_RCV_NEIGH,TMP_INDEX_SEND_NEIGH)
!$COMMENT
!       SPMD_CHECK_ALE_NEIGHBOUR description
!           SPMD_CHECK_ALE_NEIGHBOUR exchange the deactivated ALE elements
!       SPMD_CHECK_ALE_NEIGHBOUR organization
!           The neighbourhood is re-built in this routine
!           * a deactivated element is removed from the list of neighbour
!           * neighbourhood array is saved before its modification
!           * saved neighbourhood array is written in the restart file
!
!$ENDCOMMENT
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "com01_c.inc"
#include "com04_c.inc"
#include "task_c.inc"
#include "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, DIMENSION(SNESDVOIS), INTENT(IN) :: NB_SEND_NEIGH
        INTEGER, DIMENSION(SNERCVOIS), INTENT(IN) :: NB_RCV_NEIGH
        INTEGER, DIMENSION(SLESDVOIS), INTENT(IN) :: INDEX_SEND_NEIGH
        INTEGER, DIMENSION(SLERCVOIS), INTENT(IN) :: INDEX_RCV_NEIGH
 
        INTEGER, DIMENSION(SNESDVOIS), INTENT(INOUT) :: TMP_NB_SEND_NEIGH
        INTEGER, DIMENSION(SNERCVOIS), INTENT(INOUT) :: TMP_NB_RCV_NEIGH
        INTEGER, DIMENSION(SLESDVOIS), INTENT(INOUT) :: TMP_INDEX_SEND_NEIGH
        INTEGER, DIMENSION(SLERCVOIS), INTENT(INOUT) :: TMP_INDEX_RCV_NEIGH
        INTEGER, INTENT(IN) :: LENCOM
        LOGICAL, DIMENSION(NUMELS+NUMELQ+NUMELTG), INTENT(IN) :: ACTIVE_ELEMENT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
        INTEGER I, IDEB, IDEB2, MSGOFF, IERROR,MSGTYP,IAD_RECV(NSPMD),
     .        STATUS(MPI_STATUS_SIZE), REQ_S(NSPMD), REQ_R(NSPMD),
     .        LOC_PROC, N, NN, NBIRECV, IRINDEX(NSPMD), II, INDEX,
     .        len
        DATA msgoff/3003/
        LOGICAL, DIMENSION(:), ALLOCATABLE :: WA
C-----------------------------------------------
        ALLOCATE( wa(lencom) )
 
        ! -------------------
        ! receive the data 
        loc_proc = ispmd+1
        ideb = 0
        ideb2 = 0
        nbirecv = 0
        DO i = 1, nspmd
            msgtyp = msgoff 
            iad_recv(i) = ideb2+1
            IF(nb_rcv_neigh(i)>0) THEN
                nbirecv = nbirecv + 1
                irindex(nbirecv) = i
                len = nb_rcv_neigh(i)
                CALL mpi_irecv( wa(ideb2+1),len,mpi_logical,it_spmd(i),msgtyp,
     .                          spmd_comm_world,req_r(nbirecv),ierror)
                ideb2 = ideb2 + len
            ENDIF
        ENDDO
        ! -------------------
 
        ! -------------------
        ! send the data & build the deactivated element neighbours for send
        ideb = 0
        DO i = 1, nspmd
            msgtyp = msgoff 
            len = nb_send_neigh(i)
            tmp_nb_send_neigh(i) = 0
            IF(len>0) THEN
                DO n = 1, len
                    nn = index_send_neigh(ideb+n)
                    wa(ideb2+n) = active_element(nn)
                    IF(wa(ideb2+n)) THEN
                        tmp_nb_send_neigh(i) = tmp_nb_send_neigh(i) + 1
                        tmp_index_send_neigh(ideb+tmp_nb_send_neigh(i)) = index_send_neigh(ideb+n)
                    ENDIF
                ENDDO
                CALL mpi_isend( wa(ideb2+1),len,mpi_logical,it_spmd(i),msgtyp,
     .                          spmd_comm_world,req_s(i),ierror)
                ideb = ideb + len
                ideb2 = ideb2 + len
            ENDIF
        ENDDO
        ! -------------------
 
        ! -------------------
        ! wait the R message & build the deactivated element neighbours for rcv
        DO ii = 1, nbirecv
            CALL mpi_waitany(nbirecv,req_r,index,status,ierror)
            i = irindex(index)
            tmp_nb_rcv_neigh(i) = 0
            ideb = iad_recv(i)-1
            DO n = 1, nb_rcv_neigh(i)
                nn = index_rcv_neigh(ideb+n)
                IF(wa(ideb+n)) THEN
                    tmp_nb_rcv_neigh(i) = tmp_nb_rcv_neigh(i) + 1
                    tmp_index_rcv_neigh(ideb+tmp_nb_rcv_neigh(i)) = index_rcv_neigh(ideb+n)
                ENDIF
            ENDDO
        ENDDO
        ! -------------------
 
        ! -------------------
        ! wait the S message
        DO i = 1, nspmd
            IF(nb_send_neigh(i)>0) THEN
                CALL mpi_wait(req_s(i),status,ierror)
            ENDIF
        ENDDO
        ! -------------------
        DEALLOCATE( wa )
#endif
      RETURN
      END SUBROUTINE spmd_check_ale_neighbour