spmd_check_ale_neighbour.F File Reference

#include "implicit_f.inc"
#include "spmd.inc"
#include "com01_c.inc"
#include "com04_c.inc"
#include "task_c.inc"
#include "tabsiz_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	spmd_check_ale_neighbour (active_element, nb_rcv_neigh, nb_send_neigh, index_rcv_neigh, index_send_neigh, lencom, tmp_nb_rcv_neigh, tmp_nb_send_neigh, tmp_index_rcv_neigh, tmp_index_send_neigh)

Function/Subroutine Documentation

spmd_check_ale_neighbour()

subroutine spmd_check_ale_neighbour	(	logical, dimension(numels+numelq+numeltg), intent(in)	active_element,
		integer, dimension(snercvois), intent(in)	nb_rcv_neigh,
		integer, dimension(snesdvois), intent(in)	nb_send_neigh,
		integer, dimension(slercvois), intent(in)	index_rcv_neigh,
		integer, dimension(slesdvois), intent(in)	index_send_neigh,
		integer, intent(in)	lencom,
		integer, dimension(snercvois), intent(inout)	tmp_nb_rcv_neigh,
		integer, dimension(snesdvois), intent(inout)	tmp_nb_send_neigh,
		integer, dimension(slercvois), intent(inout)	tmp_index_rcv_neigh,
		integer, dimension(slesdvois), intent(inout)	tmp_index_send_neigh )

Definition at line 29 of file spmd_check_ale_neighbour.F.

!$COMMENT
!       SPMD_CHECK_ALE_NEIGHBOUR description
!           SPMD_CHECK_ALE_NEIGHBOUR exchange the deactivated ALE elements
!       SPMD_CHECK_ALE_NEIGHBOUR organization
!           The neighbourhood is re-built in this routine
!           * a deactivated element is removed from the list of neighbour
!           * neighbourhood array is saved before its modification
!           * saved neighbourhood array is written in the restart file
!
!$ENDCOMMENT
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include "com01_c.inc"
#include "com04_c.inc"
#include "task_c.inc"
#include "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, DIMENSION(SNESDVOIS), INTENT(IN) :: NB_SEND_NEIGH
        INTEGER, DIMENSION(SNERCVOIS), INTENT(IN) :: NB_RCV_NEIGH
        INTEGER, DIMENSION(SLESDVOIS), INTENT(IN) :: INDEX_SEND_NEIGH
        INTEGER, DIMENSION(SLERCVOIS), INTENT(IN) :: INDEX_RCV_NEIGH
 
        INTEGER, DIMENSION(SNESDVOIS), INTENT(INOUT) :: TMP_NB_SEND_NEIGH
        INTEGER, DIMENSION(SNERCVOIS), INTENT(INOUT) :: TMP_NB_RCV_NEIGH
        INTEGER, DIMENSION(SLESDVOIS), INTENT(INOUT) :: TMP_INDEX_SEND_NEIGH
        INTEGER, DIMENSION(SLERCVOIS), INTENT(INOUT) :: TMP_INDEX_RCV_NEIGH
        INTEGER, INTENT(IN) :: LENCOM
        LOGICAL, DIMENSION(NUMELS+NUMELQ+NUMELTG), INTENT(IN) :: ACTIVE_ELEMENT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
        INTEGER I, IDEB, IDEB2, MSGOFF, IERROR,MSGTYP,IAD_RECV(NSPMD),
     .        STATUS(MPI_STATUS_SIZE), REQ_S(NSPMD), REQ_R(NSPMD),
     .        LOC_PROC, N, NN, NBIRECV, IRINDEX(NSPMD), II, INDEX,
     .        LEN
        DATA msgoff/3003/
        LOGICAL, DIMENSION(:), ALLOCATABLE :: WA
C-----------------------------------------------
        ALLOCATE( wa(lencom) )
 
        ! -------------------
        ! receive the data 
        loc_proc = ispmd+1
        ideb = 0
        ideb2 = 0
        nbirecv = 0
        DO i = 1, nspmd
            msgtyp = msgoff 
            iad_recv(i) = ideb2+1
            IF(nb_rcv_neigh(i)>0) THEN
                nbirecv = nbirecv + 1
                irindex(nbirecv) = i
                len = nb_rcv_neigh(i)
                CALL mpi_irecv( wa(ideb2+1),len,mpi_logical,it_spmd(i),msgtyp,
     .                          spmd_comm_world,req_r(nbirecv),ierror)
                ideb2 = ideb2 + len
            ENDIF
        ENDDO
        ! -------------------
 
        ! -------------------
        ! send the data & build the deactivated element neighbours for send
        ideb = 0
        DO i = 1, nspmd
            msgtyp = msgoff 
            len = nb_send_neigh(i)
            tmp_nb_send_neigh(i) = 0
            IF(len>0) THEN
                DO n = 1, len
                    nn = index_send_neigh(ideb+n)
                    wa(ideb2+n) = active_element(nn)
                    IF(wa(ideb2+n)) THEN
                        tmp_nb_send_neigh(i) = tmp_nb_send_neigh(i) + 1
                        tmp_index_send_neigh(ideb+tmp_nb_send_neigh(i)) = index_send_neigh(ideb+n)
                    ENDIF
                ENDDO
                CALL mpi_isend( wa(ideb2+1),len,mpi_logical,it_spmd(i),msgtyp,
     .                          spmd_comm_world,req_s(i),ierror)
                ideb = ideb + len
                ideb2 = ideb2 + len
            ENDIF
        ENDDO
        ! -------------------
 
        ! -------------------
        ! wait the R message & build the deactivated element neighbours for rcv
        DO ii = 1, nbirecv
            CALL mpi_waitany(nbirecv,req_r,index,status,ierror)
            i = irindex(index)
            tmp_nb_rcv_neigh(i) = 0
            ideb = iad_recv(i)-1
            DO n = 1, nb_rcv_neigh(i)
                nn = index_rcv_neigh(ideb+n)
                IF(wa(ideb+n)) THEN
                    tmp_nb_rcv_neigh(i) = tmp_nb_rcv_neigh(i) + 1
                    tmp_index_rcv_neigh(ideb+tmp_nb_rcv_neigh(i)) = index_rcv_neigh(ideb+n)
                ENDIF
            ENDDO
        ENDDO
        ! -------------------
 
        ! -------------------
        ! wait the S message
        DO i = 1, nspmd
            IF(nb_send_neigh(i)>0) THEN
                CALL mpi_wait(req_s(i),status,ierror)
            ENDIF
        ENDDO
        ! -------------------
        DEALLOCATE( wa )
#endif
      RETURN