xfem_crk_dir.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    xfem_crk_dir    ../engine/source/elements/xfem/xfem_crk_dir.F
!||--- called by ------------------------------------------------------
!||    mulawc          ../engine/source/materials/mat_share/mulawc.F90
!||    usermat_shell   ../engine/source/materials/mat_share/usermat_shell.F
!||====================================================================
      SUBROUTINE xfem_crk_dir(NEL   ,ILAY  ,IXFEM   ,ELCRKINI,
     .                        DIR_A ,TENS  ,DIR1_CRK,DIR2_CRK,IROT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include   "implicit_f.inc"
#include   "com_xfem1.inc"
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL,ILAY,IXFEM,IROT
      INTEGER ELCRKINI(NXLAYMAX,*)
      my_real dir_a(nel,2),tens(nel,5),dir1_crk(nxlaymax,nel),
     .   dir2_crk(nxlaymax,nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER JCT(NEL)
      INTEGER I,IR,NEWCRK
      my_real cc,bb,cr,orm,ss1,ss2,s1,s2,s3,s4,s5
C=======================================================================
      newcrk = 0
      DO i=1,nel
        jct(i) = 0
        IF (abs(elcrkini(ilay,i)) == 1) THEN  ! new crack (init or adv)
          newcrk = newcrk + 1
          jct(newcrk) = i
        ENDIF
      ENDDO
      IF (newcrk == 0) RETURN
c------------------------------------------
c     crack directions dans le repere coque
c------------------------------------------
      IF (irot > 0) THEN
        DO ir=1,newcrk
          i  = jct(ir)            
          s1 = dir_a(i,1)*dir_a(i,1)*tens(i,1)
     .       + dir_a(i,2)*dir_a(i,2)*tens(i,2)
     .       - two*dir_a(i,1)*dir_a(i,2)*tens(i,3)
          s2 = dir_a(i,2)*dir_a(i,2)*tens(i,1)
     .       + dir_a(i,1)*dir_a(i,1)*tens(i,2)
     .       + two*dir_a(i,2)*dir_a(i,1)*tens(i,3)
          s3 = dir_a(i,1)*dir_a(i,2)*tens(i,1)
     .       - dir_a(i,2)*dir_a(i,1)*tens(i,2)
     .       +(dir_a(i,1)*dir_a(i,1)-dir_a(i,2)*dir_a(i,2))*tens(i,3)
          s4 = dir_a(i,2)*tens(i,5)+dir_a(i,1)*tens(i,4)
          s5 = dir_a(i,1)*tens(i,5)-dir_a(i,2)*tens(i,4)
          tens(i,1) = s1
          tens(i,2) = s2
          tens(i,3) = s3
          tens(i,4) = s4
          tens(i,5) = s5
        ENDDO
      ENDIF                               
c
      DO ir=1,newcrk
        i   = jct(ir)              
        cc  = (tens(i,1)+tens(i,2))*half      
        bb  = (tens(i,1)-tens(i,2))*half      
        cr  = sqrt(bb*bb+tens(i,3)*tens(i,3))   
        ss1 = cc+cr                             
        ss2 = cc-cr                             
        dir1_crk(ilay,i) = tens(i,3)              
        dir2_crk(ilay,i) = ss1-tens(i,1)          
        orm = dir1_crk(ilay,i)*dir1_crk(ilay,i)+   
     .        dir2_crk(ilay,i)*dir2_crk(ilay,i)    
        orm = sqrt(orm)                          
        IF (orm < em8) THEN                      
          dir1_crk(ilay,i)=one                   
          dir2_crk(ilay,i)=zero                 
        ELSE                                   
          dir1_crk(ilay,i)=dir1_crk(ilay,i)/orm  
          dir2_crk(ilay,i)=dir2_crk(ilay,i)/orm  
        ENDIF                                  
      ENDDO                                    
C-----------
      RETURN
      END