zqrt05.f

Go to the documentation of this file.

*> \brief \b ZQRT05
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZQRT05(M,N,L,NB,RESULT)
*
*       .. Scalar Arguments ..
*       INTEGER LWORK, M, N, L, NB, LDT
*       .. Return values ..
*       DOUBLE PRECISION RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZQRT05 tests ZTPQRT and ZTPMQRT.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in lower part of the test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*>
*> \param[in] L
*> \verbatim
*>          L is INTEGER
*>          The number of rows of the upper trapezoidal part the
*>          lower test matrix.  0 <= L <= M.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Block size of test matrix.  NB <= N.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R |
*>          RESULT(2) = | I - Q^H Q |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q |
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zqrt05(M,N,L,NB,RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER LWORK, M, N, L, NB, LDT
*     .. Return values ..
      DOUBLE PRECISION RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      COMPLEX*16, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
      DOUBLE PRECISION, ALLOCATABLE :: RWORK(:)
*
*     .. Parameters ..
      DOUBLE PRECISION ZERO
      COMPLEX*16 ONE, CZERO
      parameter( zero = 0.0, one = (1.0,0.0), czero=(0.0,0.0) )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, M2, NP1
      DOUBLE PRECISION ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DLAMCH
      DOUBLE PRECISION ZLANGE, ZLANSY
      LOGICAL  LSAME
      EXTERNAL dlamch, zlange, zlansy, lsame
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = dlamch( 'Epsilon' )
      k = n
      m2 = m+n
      IF( m.GT.0 ) THEN
         np1 = n+1
      ELSE
         np1 = 1
      END IF
      lwork = m2*m2*nb
*
*     Dynamically allocate all arrays
*
      ALLOCATE(a(m2,n),af(m2,n),q(m2,m2),r(m2,m2),rwork(m2),
     $           work(lwork),t(nb,n),c(m2,n),cf(m2,n),
     $           d(n,m2),df(n,m2) )
*
*     Put random stuff into A
*
      ldt=nb
      CALL zlaset( 'Full', m2, n, czero, czero, a, m2 )
      CALL zlaset( 'Full', nb, n, czero, czero, t, nb )
      DO j=1,n
         CALL zlarnv( 2, iseed, j, a( 1, j ) )
      END DO
      IF( m.GT.0 ) THEN
         DO j=1,n
            CALL zlarnv( 2, iseed, m-l, a( min(n+m,n+1), j ) )
         END DO
      END IF
      IF( l.GT.0 ) THEN
         DO j=1,n
            CALL zlarnv( 2, iseed, min(j,l), a( min(n+m,n+m-l+1), j ) )
         END DO
      END IF
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m2, n, a, m2, af, m2 )
*
*     Factor the matrix A in the array AF.
*
      CALL ztpqrt( m,n,l,nb,af,m2,af(np1,1),m2,t,ldt,work,info)
*
*     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
*
      CALL zlaset( 'full', M2, M2, CZERO, ONE, Q, M2 )
      CALL ZGEMQRT( 'r', 'n', M2, M2, K, NB, AF, M2, T, LDT, Q, M2,
     $              WORK, INFO )
*
*     Copy R
*
      CALL ZLASET( 'full', M2, N, CZERO, CZERO, R, M2 )
      CALL ZLACPY( 'upper', M2, N, AF, M2, R, M2 )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL ZGEMM( 'c', 'n', M2, N, M2, -ONE, Q, M2, A, M2, ONE, R, M2 )
      ANORM = ZLANGE( '1', M2, N, A, M2, RWORK )
      RESID = ZLANGE( '1', M2, N, R, M2, RWORK )
.GT.      IF( ANORMZERO ) THEN
         RESULT( 1 ) = RESID / (EPS*ANORM*MAX(1,M2))
      ELSE
         RESULT( 1 ) = ZERO
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL ZLASET( 'full', M2, M2, CZERO, ONE, R, M2 )
      CALL ZHERK( 'u', 'c', M2, M2, DREAL(-ONE), Q, M2, DREAL(ONE),
     $            R, M2 )
      RESID = ZLANSY( '1', 'upper', M2, R, M2, RWORK )
      RESULT( 2 ) = RESID / (EPS*MAX(1,M2))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO J=1,N
         CALL ZLARNV( 2, ISEED, M2, C( 1, J ) )
      END DO
      CNORM = ZLANGE( '1', M2, N, C, M2, RWORK)
      CALL ZLACPY( 'full', M2, N, C, M2, CF, M2 )
*
*     Apply Q to C as Q*C
*
      CALL ZTPMQRT( 'l','n', M,N,K,L,NB,AF(NP1,1),M2,T,LDT,CF,M2,
     $               CF(NP1,1),M2,WORK,INFO)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL ZGEMM( 'n', 'n', M2, N, M2, -ONE, Q, M2, C, M2, ONE, CF, M2 )
      RESID = ZLANGE( '1', M2, N, CF, M2, RWORK )
.GT.      IF( CNORMZERO ) THEN
         RESULT( 3 ) = RESID / (EPS*MAX(1,M2)*CNORM)
      ELSE
         RESULT( 3 ) = ZERO
      END IF
*
*     Copy C into CF again
*
      CALL ZLACPY( 'full', M2, N, C, M2, CF, M2 )
*
*     Apply Q to C as QT*C
*
      CALL ZTPMQRT( 'l','c',M,N,K,L,NB,AF(NP1,1),M2,T,LDT,CF,M2,
     $              CF(NP1,1),M2,WORK,INFO)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL ZGEMM('c','n',M2,N,M2,-ONE,Q,M2,C,M2,ONE,CF,M2)
      RESID = ZLANGE( '1', M2, N, CF, M2, RWORK )
.GT.      IF( CNORMZERO ) THEN
         RESULT( 4 ) = RESID / (EPS*MAX(1,M2)*CNORM)
      ELSE
         RESULT( 4 ) = ZERO
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO J=1,M2
         CALL ZLARNV( 2, ISEED, N, D( 1, J ) )
      END DO
      DNORM = ZLANGE( '1', N, M2, D, N, RWORK)
      CALL ZLACPY( 'full', N, M2, D, N, DF, N )
*
*     Apply Q to D as D*Q
*
      CALL ZTPMQRT('r','n',N,M,N,L,NB,AF(NP1,1),M2,T,LDT,DF,N,
     $             DF(1,NP1),N,WORK,INFO)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL ZGEMM('n','N',n,m2,m2,-one,d,n,q,m2,one,df,n)
      resid = zlange('1',n, m2,df,n,rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL zlacpy('Full',n,m2,d,n,df,n )
*
*     Apply Q to D as D*QT
*
      CALL ztpmqrt('R','C',n,m,n,l,nb,af(np1,1),m2,t,ldt,df,n,
     $             df(1,np1),n,work,info)
 
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL zgemm( 'N', 'C', n, m2, m2, -one, d, n, q, m2, one, df, n )
      resid = zlange( '1', n, m2, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
      RETURN
      END