hm_read_eos_ideal_gas.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_ideal_gas (iout, pm, unitab, iunit, lsubmodel, imideos, mat_param)

Function/Subroutine Documentation

hm_read_eos_ideal_gas()

subroutine hm_read_eos_ideal_gas	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_ideal_gas.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   IDEAL-GAS EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  gamma, p0, t0, e0, psh, rho0, cv, mu0, rhoi, rhor, g0, ssp0, dpdmu, df
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('Gamma', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('T_Initial', t0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
      
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      IF(gamma > one) THEN
        e0 = p0/(gamma-one)/(one+mu0)
      ELSE
        e0 = zero !manage this error below
      ENDIF
 
      !ERREURS :
      ! P0 <=0
      ! GAMMA <=ONE
      IF(p0 <= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/IDEAL-GAS',
     .               c2='INITIAL PRESSURE MUST BE POSITIVE')
      ENDIF
      
      IF(gamma <= one)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/IDEAL-GAS',
     .               c2='SPECIFIC HEAT RATIO (GAMMA) MUST BE GREATER THAN 1.0')
      ENDIF
 
      IF (t0 == zero) t0 = three100
      mat_param%THERM%TINI =three100
      pm(79) = three100
 
      cv = zero
      IF(rho0*t0 /= zero) THEN
        ! this situation is not expected unless in case of input inconsistency (eos_uid does not match mat_uid)
        cv = e0/rho0/t0
      ENDIF
 
      pm(23) = e0
      pm(31) = p0-psh
      pm(32) = (gamma-one)*e0 !BULK = (1+µ)*dP/dmu (partial derivative at constant E)
      pm(79) = t0
      pm(88) = psh
      pm(104)= p0-psh
 
      mat_param%EOS%NUPARAM = 3
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = gamma
      mat_param%EOS%UPARAM(2) = p0
      mat_param%EOS%UPARAM(3) = t0
      mat_param%EOS%PSH = psh
      mat_param%EOS%Cv = cv
      mat_param%EOS%Cp = gamma * cv
      mat_param%EOS%E0 = e0
      
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      dpdmu =  (gamma-one)*e0+(one+mu0)*(gamma-one)*df*df*(pm(31)+psh)
 
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0      
 
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)gamma,p0,psh,t0,e0,cv
      ENDIF
      IF(is_available_rho0)WRITE(iout,1501)pm(1)
 
      RETURN
 1000 FORMAT(
     & 5x,'  IDEAL GAS EOS     ',/,
     & 5x,'  -------------     ',/)
 1500 FORMAT(
     & 5x,'GAMMA . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSH . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'T0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'E0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'COMPUTED HEAT CAPACITY (Cv) . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13) 
      
      RETURN