hm_read_eos_nasg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_nasg         ../starter/source/materials/eos/hm_read_eos_nasg.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_nasg(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   NOBLE-ABEL-STIFFENED-GAS (NASG) EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IIN,IOUT,IUNIT
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  gamma, p0, e0, psh, rho0,fac_l,fac_t,fac_m,fac_c,pstar,rhoi,rhor,cv,t0,b,q,q_
      my_real  num,denom,unpmu
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
      my_real :: pp,dpde,dpdmu ,g0,ssp0,mu0,df
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('b_Covolume', b, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Gamma_Constant', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('P_star', pstar, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('E0', q, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_C0', cv, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      !---initial density
      rhor = pm(1)
      rhoi = pm(89)
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
      ELSE
        rho0=rhor                   
      ENDIF
      
      !---Initial State Deduced from e=eos(P0,T0) and t=eos(P0,rho0)
      t0=(one/rho0-b)*(p0+pstar)/(gamma-one)/cv      
      e0=(p0+gamma*pstar)*(one-rho0*b)/(gamma-1)+rho0*q
      
      !---warning/errors :
      ! GAMMA <=0
      
      IF(gamma <= one)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/NASG',
     .               c2='GAMMA MUST BE GREATER THAN 1.0')
      ENDIF
      
      IF(e0 <= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/NASG',
     .               c2='PARAMETERS ARE RESULTING INTO A NEGATIVE ENERGY : E0')      
      ENDIF
 
      q_ = zero
      !---buffer storage     
      pm(034)=gamma
      pm(032)=p0
      pm(088)=psh
      pm(023)=e0
      pm(160)=pstar
      pm(031)=p0
      pm(035)=q
      pm(036)=q_
      pm(161)=b
      pm(162)=cv
      pm(079)=t0
      IF(pm(79)==zero)pm(79)=three100
      
      !P0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
         
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)      
        unpmu   =  one+mu0
        denom   = (one-rhoi*b*unpmu)
        num     = (e0-rhoi*q)
        pp      = p0
        dpde    = (gamma-one)*unpmu / denom                                         !partial derivative    
        dpdmu   = (gamma-one)*num/denom/denom + dpde*(pp)/unpmu/unpmu                                  
 
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0           
   
      !---listing output
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)gamma,b,q,psh,pstar,cv,p0,e0
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  NOBLE-ABEL-STIFFENED GAS EOS',/,
     & 5x,'  ----------------------------',/)
 1500 FORMAT(
     & 5x,'GAMMA . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'b . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'q . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
!     & 5X,'q_. . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5x,'PSH . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSTAR . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'Cv. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
!     & 5X,'T0 .  . . . . . . . . . . . . . . . . . .=',1PG20.13/,     
     & 5x,'E0 .  . . . . . . . . . . . . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)     
 
      RETURN
      END