hm_read_eos_nasg.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_nasg (iout, pm, unitab, iunit, lsubmodel, imideos, mat_param)

Function/Subroutine Documentation

hm_read_eos_nasg()

subroutine hm_read_eos_nasg	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_nasg.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   NOBLE-ABEL-STIFFENED-GAS (NASG) EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT,IUNIT
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  gamma, p0, e0, psh, rho0,pstar,rhoi,rhor,cv,t0,b,q,q_
      my_real  num,denom,unpmu
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
      my_real :: pp,dpde,dpdmu ,g0,ssp0,mu0,df
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('b_Covolume', b, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Gamma_Constant', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('P_star', pstar, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('E0', q, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('LAW5_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_C0', cv, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      !---initial density
      rhor = pm(1)
      rhoi = pm(89)
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
      
      !---Initial State Deduced from e=eos(P0,T0) and t=eos(P0,rho0)
      t0=(one/rho0-b)*(p0+pstar)/(gamma-one)/cv      
      e0=(p0+gamma*pstar)*(one-rho0*b)/(gamma-1)+rho0*q
      
      !---warning/errors :
      ! GAMMA <=0
      
      IF(gamma <= one)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/NASG',
     .               c2='GAMMA MUST BE GREATER THAN 1.0')
      ENDIF
      
      IF(e0 <= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/NASG',
     .               c2='PARAMETERS ARE RESULTING INTO A NEGATIVE ENERGY : E0')      
      ENDIF
 
      q_ = zero
      !---buffer storage
      pm(032)= (e0-rho0*q)*(gamma-one)/(one-rho0*b) !BULK = (1+µ)*dP/dmu (partial derivative at constant E)
      pm(088)=psh
      pm(023)=e0
      pm(031)=p0
 
      mat_param%EOS%NUPARAM = 7
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = gamma
      mat_param%EOS%UPARAM(2) = p0
      mat_param%EOS%UPARAM(3) = pstar
      mat_param%EOS%UPARAM(4) = q
      mat_param%EOS%UPARAM(5) = q_
      mat_param%EOS%UPARAM(6) = b
      mat_param%EOS%UPARAM(7) = rho0
 
      mat_param%EOS%PSH = psh
      mat_param%EOS%CV = cv
      mat_param%EOS%E0 = e0
      IF (t0 == zero) t0 = three100
      mat_param%THERM%TINI =t0
      pm(79) = t0
      
      !P0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
         
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)      
        unpmu   =  one+mu0
        denom   = (one-rhoi*b*unpmu)
        num     = (e0-rhoi*q)
        pp      = p0
        dpde    = (gamma-one)*unpmu / denom                                         !partial derivative    
        dpdmu   = (gamma-one)*num/denom/denom + dpde*(pp)/unpmu/unpmu                                  
 
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor)
      pm(32) = dpdmu ! bulk modulus
      pm(27) = ssp0
   
      !---listing output
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)gamma,b,q,psh,pstar,cv,p0,e0
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  NOBLE-ABEL-STIFFENED GAS EOS',/,
     & 5x,'  ----------------------------',/)
 1500 FORMAT(
     & 5x,'GAMMA . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'b . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'q . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSH . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PSTAR . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'Cv. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'E0 .  . . . . . . . . . . . . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)     
 
      RETURN