hm_read_eos_osborne.F File Reference

#include "my_real.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_osborne (iout, pm, unitab, iunit, lsubmodel, imideos, mat_param)

Function/Subroutine Documentation

hm_read_eos_osborne()

subroutine hm_read_eos_osborne	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 35 of file hm_read_eos_osborne.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE constant_mod, ONLY : zero, one, two, three100, four, half, four, two_third
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   OSBORNE EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
      IMPLICIT NONE
#include "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real  p0, e0, psh, rho0
      my_real a1,a2,b0,b1,b2,c0,c1,d0,rhoi,rhor,dpdmu_partial,dpde,df,mu0,dpdmu,a2_,g0,ssp0, denom
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('EOS_A1', a1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_A2', a2, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_B0', b0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_B1', b1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_B2', b2, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('EOS_C0', c0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_C_1', c1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_D0', d0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_P0', p0, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
            
      IF(
     .   a1 <= zero .OR.
     .   a2 <= zero .OR.
     .   b0 <= zero .OR.
     .   b1 <= zero .OR.
     .   b2 <= zero .OR.
     .   c0 <= zero .OR.
     .   c1 <= zero .OR.
     .   d0 <= zero .OR.
     .   rho0 <= zero 
     .   )THEN
         CALL ancmsg(msgid=67, msgtype=msgerror, anmode=aninfo,
     .               i1=imideos,
     .               c1='/EOS/OSBORNE',
     .               c2='PARAMETERS MUST BE STRICTLY POSITIVE')
      ENDIF
 
      !solve P(0,E0)=P0  :  2 roots
      !E0 =-HALF*(B0-P0+SQRT(FOUR*C0*D0*P0+B0**TWO-TWO*B0*P0+P0**TWO))/C0  !root-1
      e0 =-half*(b0-p0-sqrt(four*c0*d0*p0+b0**two-two*b0*p0+p0**two))/c0   !root-2
      
      
      pm(23) = e0
      pm(32) = (a1+b1+c1*e0*e0) / (e0+d0) !BULK = (1+µ)*dP/dmu (partial derivative at constant E)
      psh    = zero
      pm(88) = psh
      pm(31) = p0
 
      mat_param%EOS%NUPARAM = 9
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = a1
      mat_param%EOS%UPARAM(2) = a2
      mat_param%EOS%UPARAM(3) = b0
      mat_param%EOS%UPARAM(4) = b1
      mat_param%EOS%UPARAM(5) = b2
      mat_param%EOS%UPARAM(6) = c0
      mat_param%EOS%UPARAM(7) = c1
      mat_param%EOS%UPARAM(8) = d0
      mat_param%EOS%UPARAM(9) = p0
 
      mat_param%EOS%PSH = psh
      mat_param%EOS%E0 = e0
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      !P0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      
      a2_=a2                                                                              
      IF(mu0 < zero)a2_=-a2                                                               
      denom   = (e0+d0)                                                                   
      dpdmu_partial   = (a1+2*a2_*mu0+(two*b2*mu0+b1)*e0+c1*e0*e0)/denom                 
      dpde = (((b2*mu0+b1)*mu0+b0)+(two*(c1*mu0+c0))*e0 - p0/denom)/denom                                         
      dpdmu = dpdmu_partial + dpde*df*df*(p0)   !total derivative                         
      
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0            
 
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)a1,a2,b0,b1,b2,c0,c1,d0,p0
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  OSBORNE EOS     ',/,
     & 5x,'  -----------     ',/)
 1500 FORMAT(
     & 5x,'A1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'A2. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'B0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'B1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'B2. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'D0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'P0. . . . . . . . . . . . . . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)      
 
      RETURN