hm_read_eos_polynomial.F File Reference

#include "implicit_f.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_eos_polynomial (iout, pm, unitab, iunit, lsubmodel, imideos, isfluid, mat_param)

Function/Subroutine Documentation

hm_read_eos_polynomial()

subroutine hm_read_eos_polynomial	(	integer	iout,
			pm,
		type (unit_type_), intent(in)	unitab,
		integer	iunit,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		integer, intent(in)	imideos,
		integer, intent(inout)	isfluid,
		type(matparam_struct_), intent(inout)	mat_param )

Definition at line 34 of file hm_read_eos_polynomial.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   POLYNOMIAL EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT
      my_real pm(npropm)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(MATPARAM_STRUCT_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
      INTEGER,INTENT(INOUT) :: ISFLUID
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real :: c0, c1, c2, c3, c4, c5, c6, e0, psh, rho0,rhor,mu0,mu02,rhoi, g0, ssp0, df, dpdmu
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0     
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_C0', c0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C1', c1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C2', c2, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C3', c3, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C4', c4, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C5', c5, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_C6', c6, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_EA', e0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0, is_available_rho0,lsubmodel,unitab)
!-------------------------------------------------------------------------------
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
        mat_param%RHO = rho0
      ELSE
        rho0=rhor                   
      ENDIF
 
      pm(23)=e0
      !PM(32) = C1 !legacy value
      pm(32)=c1+c4*e0    !BULK MODULUS = (1+µ)*dP/dmu (partial derivative at constant E)
      pm(88)=psh
 
      mat_param%EOS%NUPARAM = 7
      mat_param%EOS%NIPARAM = 0
      mat_param%EOS%NFUNC = 0
      mat_param%EOS%NTABLE = 0
      CALL mat_param%EOS%CONSTRUCT() !allocations
 
      mat_param%EOS%UPARAM(1) = c0-psh
      mat_param%EOS%UPARAM(2) = c1
      mat_param%EOS%UPARAM(3) = c2
      mat_param%EOS%UPARAM(4) = c3
      mat_param%EOS%UPARAM(5) = c4
      mat_param%EOS%UPARAM(6) = c5
      mat_param%EOS%UPARAM(7) = c6
      mat_param%EOS%PSH = psh
      mat_param%EOS%E0 = e0
      IF (mat_param%THERM%TINI == zero) THEN
        mat_param%THERM%TINI =three100
        pm(79) = three100
      END IF
 
      !initial pressure for stress tensor
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      mu02 = mu0*max(zero,mu0)
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero 
      ENDIF
 
      pm(31) = c0-psh+c1*mu0+c2*mu02+c3*mu0**3+(c4+c5*mu0+c6*mu02)*e0
      pm(104) = c0-psh
      
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      dpdmu = c1 + two*c2*max(zero,mu0) + three*c3*mu0*mu0 + (c5+c6*max(zero,mu0))*e0 + (c4 +c5*mu0 +c6*mu02)*df*df*(pm(31)+psh)
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0
 
      IF(c1 == zero .AND. c2 == zero .AND. c3 == zero .AND. c4 == c5 .AND. c4 > one .AND. c6 == zero)THEN
        isfluid = 1
      ENDIF
 
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)c0,c1,c2,c3,c4,c5,c6,e0,pm(104),psh
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  POLYNOMIAL EOS     ',/,
     & 5x,'  --------------     ',/)
 1500 FORMAT(
     & 5x,'C0. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C2. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C3. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C4. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C5. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C6. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'INITIAL INTERNAL ENERGY PER UNIT VOLUME .=',1pg20.13/,
     & 5x,'INITIAL PRESSURE. . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'PRESSURE SHIFT. . . . . . . . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)      
 
      RETURN