hm_read_initemp.F File Reference

#include "implicit_f.inc"
#include "com01_c.inc"
#include "com04_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_initemp (temp, nintemp, itherm_fe, itab, itabm1, igrnod, initids, unitab, lsubmodel)

Function/Subroutine Documentation

hm_read_initemp()

subroutine hm_read_initemp	(		temp,
		integer, intent(in)	nintemp,
		integer, intent(in)	itherm_fe,
		integer, dimension(*)	itab,
		integer, dimension(*)	itabm1,
		type (group_), dimension(ngrnod)	igrnod,
		integer, dimension(*)	initids,
		type (unit_type_), intent(in)	unitab,
		type(submodel_data), dimension(*), intent(in)	lsubmodel )

Definition at line 43 of file hm_read_initemp.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB
      INTEGER ITAB(*), ITABM1(*),INITIDS(*)
      INTEGER ,INTENT(IN) :: NINTEMP
      INTEGER ,INTENT(IN) :: ITHERM_FE
      my_real :: temp(*)
      TYPE(SUBMODEL_DATA),INTENT(IN)::LSUBMODEL(*)
C-----------------------------------------------
      TYPE (GROUP_)  , DIMENSION(NGRNOD)  :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,N,NNOD,NOSYS,ITYPE,ID,ISK,IGR,IGRS,NBTEMP,BID,
     .        FLAG_FMT,FLAG_FMT_TMP,IFIX_TMP,UID,TYP,NOD,NODSYS,NB_LINE
      my_real
     .  temp0
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER(LEN=NCHARKEY) :: KEY
      LOGICAL IS_AVAILABLE
      my_real, DIMENSION(:), ALLOCATABLE :: list_temp0
      INTEGER, DIMENSION(:), ALLOCATABLE :: LIST_NOD
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS, USRTOS
      DATA mess/'INITIAL TEMPERATURE DEFINITION           '/
C=======================================================================
      bid =0
      nbtemp = 0
      is_available = .false.   
      nb_line = 0                      
C--------------------------------------------------
C START BROWSING MODEL INITEMP
C--------------------------------------------------
      CALL hm_option_start('/INITEMP')
C--------------------------------------------------
C BROWSING /INITEMP OPTIONS 1->NRADIA 
C--------------------------------------------------
      DO i=1,nintemp
        titr = ''
        CALL hm_option_read_key(lsubmodel,
     .                      unit_id = uid,
     .                      option_id = id,
     .                      option_titr = titr)
 
!        IF (ITHERM_FE == 0) THEN
!          CALL ANCMSG(MSGID=858,
!     .                MSGTYPE=MSGERROR,
!     .                ANMODE=ANINFO)
!        ENDIF
C--------------------------------------------------
C EXTRACT DATAS (INTEGER VALUES)
C--------------------------------------------------
        CALL hm_get_intv('distribution',typ,is_available,lsubmodel)
        CALL hm_get_intv('entityid',igr,is_available,lsubmodel)
        IF (typ == 1) THEN
          CALL hm_get_intv('grnd_ID',igr,is_available,lsubmodel)
          CALL hm_get_intv('distribution_table_count',nb_line,is_available,lsubmodel)
          IF(.NOT.ALLOCATED(list_nod)) ALLOCATE(list_nod(nb_line))
          list_nod(1:nb_line) = 0
          IF(.NOT.ALLOCATED(list_temp0)) ALLOCATE(list_temp0(nb_line))
          list_temp0(1:nb_line) = zero
          DO j=1,nb_line
            CALL hm_get_int_array_index('location_unit_node',list_nod(j),j,is_available,lsubmodel)
          ENDDO
        ENDIF
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
        IF (typ == 0) THEN
          CALL hm_get_floatv('magnitude',temp0,is_available,lsubmodel,unitab)
        ELSEIF (typ == 1) THEN
          CALL hm_get_float_array_index('T0',temp0,j,is_available,lsubmodel,unitab)
          DO j=1,nb_line
            CALL hm_get_float_array_index('magnitude',list_temp0(j),j,is_available,lsubmodel,unitab)
          ENDDO
        ENDIF
C--------------------------------------------------  
        nbtemp = nbtemp+1
        initids(nbtemp)=id              
        igrs=0     
        IF (typ == 0) THEN                                           
          IF (igr == 0)THEN 
            CALL ancmsg(msgid=668,
     .                  msgtype=msgerror,
     .                  anmode=aninfo,
     .                  c1='/INITEM',
     .                  c2='/INITEM',
     .                  c3=titr,
     .                  i1=id)
          ENDIF                                                       
          DO j=1,ngrnod                                               
            IF (igr == igrnod(j)%ID) igrs=j
          ENDDO                                                       
          IF(igrs /= 0)THEN                                           
            DO j=1,igrnod(igrs)%NENTITY
              nosys=igrnod(igrs)%ENTITY(j)
              temp(nosys)= temp0
            ENDDO                                                     
            nnod=igrnod(igrs)%NENTITY
          ELSE
            CALL ancmsg(msgid=53,
     .                  msgtype=msgerror,
     .                  anmode=aninfo,
     .                  c1='IN /INITEM OPTION',
     .                  i1=igr)
          ENDIF   
        ELSE                                                   
          DO j=1,ngrnod                                               
            IF (igr == igrnod(j)%ID) igrs=j
          ENDDO                                                       
          IF(igrs /= 0)THEN                                           
            DO j=1,igrnod(igrs)%NENTITY
              nosys=igrnod(igrs)%ENTITY(j)
              temp(nosys)= temp0
            ENDDO                                                     
            nnod=igrnod(igrs)%NENTITY
          ENDIF      
          DO j=1,nb_line
            nodsys=usr2sys(list_nod(j),itabm1,mess,id)
            IF (list_nod(j) == 0) THEN
              CALL ancmsg(msgid=78,
     .                    msgtype=msgerror,
     .                    anmode=aninfo,
     .                    c1='/INITEM',
     .                    i1=id,  
     .                    i2=nod)
            ENDIF
            IF (nodsys /= 0) temp(nodsys)= list_temp0(j)
          ENDDO 
        ENDIF 
        IF(ALLOCATED(list_temp0)) DEALLOCATE(list_temp0) 
        IF(ALLOCATED(list_nod)) DEALLOCATE(list_nod) 
       ENDDO  
C---                                                           
      CALL udouble(initids,1,nbtemp,mess,0,bid)
C--------------------------------------------------
C     PRINT
C--------------------------------------------------
      j=0
      RETURN
C
2000  FORMAT(/, ' INITIAL TEMPERATURE ',/' -------------------',//
     + 6x,'NODE',17x,'TEMP ' )
      RETURN