hm_read_prop19.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "com04_c.inc"
#include "param_c.inc"
#include "scr17_c.inc"
#include "drape_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_read_prop19 (ig, igtyp, istack, geo, igeo, pm, ipm, unitab, idrapeid, lsubmodel)

Function/Subroutine Documentation

hm_read_prop19()

subroutine hm_read_prop19	(	integer, intent(in)	ig,
		integer, intent(in)	igtyp,
		integer, intent(in)	istack,
		dimension(npropg), intent(inout)	geo,
		integer, dimension(npropgi), intent(inout)	igeo,
		dimension(npropm,*), intent(in)	pm,
		integer, dimension(npropmi,*), intent(in)	ipm,
		type (unit_type_), intent(in)	unitab,
		integer, dimension(*), intent(in)	idrapeid,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel )

Definition at line 39 of file hm_read_prop19.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
#include      "drape_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_), INTENT(IN) ::UNITAB
      INTEGER, INTENT(INOUT) :: IGEO(NPROPGI)
      INTEGER, INTENT(IN) :: IPM(NPROPMI,*), IDRAPEID(*), IG, IGTYP, ISTACK
      my_real, INTENT(INOUT) :: geo(npropg)
      my_real, INTENT(IN) ::  pm(npropm,*)
      TYPE(SUBMODEL_DATA), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: IMID, J, DRAPE_ID, ID
      my_real :: thickt, fac_gen, pun
      CHARACTER(LEN = NCHARTITLE) :: TITR, TITR1, IDTITL
      LOGICAL :: IS_AVAILABLE, IS_ENCRYPTED, LFOUND
C-------------------------------------------------
C     B e g i n n i n g   o f  S u b r o u t i n e
C-------------------------------------------------
      pun = 0.1
      igeo(1) = ig
      igeo(11) = igtyp
      geo(12) = igtyp + pun
      
      is_available = .false.
      is_encrypted = .false.
!     encryption flag
      CALL hm_option_is_encrypted(is_encrypted)      
!     Line 1
      CALL hm_get_intv('material', imid, is_available, lsubmodel)
      CALL hm_get_floatv('thickness1', geo(1), is_available, lsubmodel, unitab)  
      CALL hm_get_floatv('orientangle', geo(2), is_available, lsubmodel, unitab)  
      CALL hm_get_intv('grsh4n_ID', igeo(40), is_available, lsubmodel)
      CALL hm_get_intv('grsh3n_ID', igeo(41), is_available, lsubmodel)
      CALL hm_get_intv('integrationpoints', igeo(4), is_available, lsubmodel)
      CALL hm_get_floatv('orientangle2', geo(212), is_available, lsubmodel, unitab)  
!     Line 2
      CALL hm_get_intv('table', drape_id, is_available, lsubmodel)
      
      IF (igeo(4) <= 0) igeo(4) = 1   ! default value
      igeo(44) = igeo(4) ! Used with drape for OUPT
      IF (geo(212) == zero) THEN
         CALL hm_get_floatv_dim('orientangle2',fac_gen, is_available, lsubmodel, unitab)
         geo(212) = ninty * fac_gen ! default value   
      ENDIF
 
      IF (is_encrypted) THEN
         WRITE(iout, 1000) ig
      ELSE
         WRITE(iout, 2000) ig, imid, geo(1), geo(2), igeo(40), igeo(41), igeo(4),
     .        geo(212), drape_id
      ENDIF
     
      geo(2) = geo(2) * pi / hundred80
      geo(212) = geo(212) * pi / hundred80
      igeo(48) = 0 
 
!     *********************************************************    !
!     Check for layer materials compatibility moved to "lecgeo"
!     *********************************************************    !
      lfound = .false.
      DO j=1,nummat-1
         IF (ipm(1,j) == imid) THEN
            igeo(101) = j
            lfound = .true.
            EXIT
         ENDIF
      ENDDO
      IF (.NOT. lfound) THEN
         CALL fretitl2(titr, igeo(npropgi-ltitr+1), ltitr)
         IF (istack == 0) THEN
            CALL ancmsg(msgid = 31, msgtype = msgerror, anmode = aninfo_blind_2,
     .           i1 = ig, c1 = titr, i2 = imid)  
         ELSE
            CALL ancmsg(msgid = 1151, msgtype = msgerror, anmode = aninfo_blind_2,
     .           i1 = ig, c1 = titr, i2 = imid) 
         ENDIF
         igeo(101) = 1   
      ELSE 
!     ***********************************    ! 
!     check for right drape id definition
!     ***********************************    ! 
         IF (ndrape > 0 .OR. drape_id > 0) THEN
            lfound = .false.
            DO j=1,ndrape
               IF (drape_id > 0 .AND. drape_id == idrapeid(j)) THEN
                  igeo(48) = drape_id
                  lfound = .true.
                  EXIT
               ENDIF 
            ENDDO
            IF (.NOT. lfound) THEN
               IF (drape_id > 0)THEN
                  CALL fretitl2(titr, igeo(npropgi-ltitr+1), ltitr)
                  CALL ancmsg(msgid = 1153, msgtype = msgerror, anmode = aninfo,
     .                 i1 = ig, c1 = titr, i2 = drape_id)
               ENDIF
            ENDIF
         ENDIF                  
      ENDIF
      IF (igeo(4) > 10) THEN
         CALL ancmsg(msgid = 788, msgtype = msgerror, anmode = aninfo,
     .        i1 = ig, c1 = idtitl)
         CALL arret(2)
      ENDIF
      RETURN
 1000 FORMAT(
     &    5x,' LAYER  SHELL PROPERTY SET'/,
     &    5x,'------------------------------------'/,
     &    5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10/,
     &    5x,'CONFIDENTIAL DATA'//)
 2000 FORMAT(
     & 5x,'LAYER PROPERTY SET ',/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . . . . . . =',i10/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . . . . . . =',i10/,
     & 5x,'LAYER THICKNESS . . . . . . . . . . . . . . . . =',1pg20.13/,
     & 5x,'INCREMENTAL ANGLE (DIR 1,PROJ(DIR 1 / SHELL). . =',1pg20.13/,      
     & 5x,'SHELL 4-nodes GROUP IDENTIFIER. . . . . . . . . =',i10/,
     & 5x,'SHELL 3-nodes GROUP IDENTIFIER. . . . . . . . . =',i10/,
     & 5x,'NUMBER OF INTEGRATION POINTS THROUGH LAYER. . . =',i10/,
     & 5x,'ORTHOTROPY ANGLE BETWEEN (DIR 1,DIR 2). . . . . =',1pg20.13/,
     & 5x,'DRAPE IDENTIFIER  . . . . . . . . . . . . . . . =',i10/)