sigeps27c.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"
#include "param_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	sigeps27c (jft, jlt, pm, thk, off, gstr, imat, dt1, ipla, shf, ngl, thk0, thklyl, crak, dam, sigy, zcfac, dpla, ilayer, ipt, israte, nel, zz, npttot, epsd_pg, depsxx, depsyy, depsxy, depsyz, depszx, sigoxx, sigoyy, sigoxy, sigoyz, sigozx, signxx, signyy, signxy, signyz, signzx, dirdmg, pla, inloc, dplanl, loff, epsd, asrate)

Function/Subroutine Documentation

sigeps27c()

subroutine sigeps27c	(	integer	jft,
		integer	jlt,
			pm,
			thk,
			off,
			gstr,
		integer	imat,
		intent(in)	dt1,
		integer	ipla,
			shf,
		integer, dimension(mvsiz)	ngl,
			thk0,
			thklyl,
			crak,
			dam,
			sigy,
			zcfac,
			dpla,
		integer	ilayer,
		integer	ipt,
		integer	israte,
		integer	nel,
			zz,
		integer	npttot,
		intent(in)	epsd_pg,
			depsxx,
			depsyy,
			depsxy,
			depsyz,
			depszx,
			sigoxx,
			sigoyy,
			sigoxy,
			sigoyz,
			sigozx,
			signxx,
			signyy,
			signxy,
			signyz,
			signzx,
			dirdmg,
			pla,
		integer	inloc,
			dplanl,
		intent(in)	loff,
		intent(inout)	epsd,
		intent(in)	asrate )

Definition at line 34 of file sigeps27c.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NGL(MVSIZ),IMAT,ILAYER,IPT,ISRATE,NPTTOT,
     .   JFT,JLT,IPLA,NEL,INLOC
      my_real, INTENT(IN) :: dt1
      my_real, INTENT(IN) :: asrate
      my_real pm(npropm,*),thk(*),off(*),gstr(nel,8),
     .   shf(*),sigy(*),zcfac(mvsiz,2),dpla(*),
     .   thk0(mvsiz),thklyl(nel),dplanl(nel)
      my_real
     .   depsxx(mvsiz),depsyy(mvsiz),depsxy(mvsiz),depsyz(mvsiz),
     .   depszx(mvsiz),sigoxx(nel),sigoyy(nel),sigoxy(nel),
     .   sigoyz(nel),sigozx(nel),signxx(nel),signyy(nel),signxy(nel),
     .   signyz(nel),signzx(nel),dirdmg(nel,2),
     .   pla(nel),crak(nel),dam(nel),zz(mvsiz)
      my_real, DIMENSION(NEL), INTENT(IN) :: loff
      my_real ,DIMENSION(NEL), INTENT(IN) :: epsd_pg
      my_real, DIMENSION(NEL) ,INTENT(INOUT) :: epsd
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   sig(nel,5),nu,strn1(mvsiz),strn2(mvsiz),strn3(mvsiz),yld(mvsiz),
     .   etse(mvsiz),zt,ezz(mvsiz),young
C=======================================================================
!
      young = pm(20,imat)
      nu    = pm(21,imat)
!
      ezz(1:mvsiz) = zero
C-----------------------------------------------------------
C     PLASTICITE AUX POINTS D'INTEGRATION
C-----------------------------------------------------------
C----------------------------
C      CONTRAINTES ELASTIQUES
C----------------------------
      DO i=jft,jlt
        sig(i,1) = sigoxx(i)
        sig(i,2) = sigoyy(i)
        sig(i,3) = sigoxy(i)
        sig(i,4) = sigoyz(i)
        sig(i,5) = sigozx(i)
      ENDDO
!
      CALL roto_sig(jft,jlt,sig,dirdmg,nel)
!
      CALL m27elas(jft    ,jlt    ,pm     ,sig    ,imat  ,
     2             depsxx ,depsyy ,depsxy ,depsyz ,depszx,
     3             dam    ,crak   ,shf    ,nel    )
C------------------------------------------
C      CONTRAINTES PLASTIQUEMENT ADMISSIBLES
C------------------------------------------
      CALL m27plas(jft    ,jlt    ,pm     ,off    ,sig   ,
     2             pla    ,imat   ,dt1    ,ipla   ,ezz   ,
     3             epsd_pg,israte ,yld    ,etse   ,dpla  ,
     4             depsxx ,depsyy ,depsxy ,depsyz ,depszx,
     5             nel    ,epsd   ,asrate )
C---------------------------------
C      RETOUR DANS LE REPERE LOCAL
C---------------------------------
      CALL uroto_sig(jft,jlt,sig,dirdmg,nel)
!
      DO i=jft,jlt
        signxx(i) = sig(i,1)
        signyy(i) = sig(i,2)
        signxy(i) = sig(i,3)
        signyz(i) = sig(i,4)
        signzx(i) = sig(i,5)
      ENDDO
C-----------------------
C     TENSILE RUPTURE
C-----------------------
      DO i=jft,jlt
        zt = zz(i)*thk0(i)
        strn1(i) = gstr(i,1)+zt*gstr(i,6)
        strn2(i) = gstr(i,2)+zt*gstr(i,7)
        strn3(i) =(gstr(i,3)+zt*gstr(i,8))*half
      ENDDO
C-----------------------
      CALL m27crak(jft    ,jlt    ,pm     ,dam    ,dirdmg ,
     2             imat   ,ilayer ,off    ,ngl    ,nel    ,
     3             strn1  ,strn2  ,strn3  )
C-----------------------
      DO i=jft,jlt
        zcfac(i,1) = zcfac(i,1) + etse(i) / npttot
        zcfac(i,2) = min(etse(i),zcfac(i,2))
        sigy(i) = min(sigy(i),yld(i))
      ENDDO
!---
!     thickness update:
!---
      DO i=jft,jlt
        IF (inloc > 0) THEN
          IF (loff(i) == one) THEN 
            ezz(i) = -nu*(signxx(i)-sigoxx(i)+signyy(i)-sigoyy(i))/young
            ezz(i) = ezz(i) - max(dplanl(i),zero)*half*(signxx(i)+signyy(i))/yld(i)
          ENDIF
        ELSE
          ezz(i) =-(depsxx(i)+depsyy(i))*nu-(one - two*nu)*ezz(i)
          ezz(i) = ezz(i)/(one-nu)
        ENDIF
        thk(i) = thk(i) + ezz(i) * thklyl(i)*off(i)
      ENDDO
C-----------
      RETURN