zpbtrf.f

Go to the documentation of this file.

*> \brief \b ZPBTRF
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZPBTRF + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zpbtrf.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zpbtrf.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zpbtrf.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZPBTRF( UPLO, N, KD, AB, LDAB, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            INFO, KD, LDAB, N
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         AB( LDAB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZPBTRF computes the Cholesky factorization of a complex Hermitian
*> positive definite band matrix A.
*>
*> The factorization has the form
*>    A = U**H * U,  if UPLO = 'U', or
*>    A = L  * L**H,  if UPLO = 'L',
*> where U is an upper triangular matrix and L is lower triangular.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          = 'U':  Upper triangle of A is stored;
*>          = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] KD
*> \verbatim
*>          KD is INTEGER
*>          The number of superdiagonals of the matrix A if UPLO = 'U',
*>          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
*> \endverbatim
*>
*> \param[in,out] AB
*> \verbatim
*>          AB is COMPLEX*16 array, dimension (LDAB,N)
*>          On entry, the upper or lower triangle of the Hermitian band
*>          matrix A, stored in the first KD+1 rows of the array.  The
*>          j-th column of A is stored in the j-th column of the array AB
*>          as follows:
*>          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
*>          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).
*>
*>          On exit, if INFO = 0, the triangular factor U or L from the
*>          Cholesky factorization A = U**H*U or A = L*L**H of the band
*>          matrix A, in the same storage format as A.
*> \endverbatim
*>
*> \param[in] LDAB
*> \verbatim
*>          LDAB is INTEGER
*>          The leading dimension of the array AB.  LDAB >= KD+1.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO = i, the leading minor of order i is not
*>                positive definite, and the factorization could not be
*>                completed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16OTHERcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The band storage scheme is illustrated by the following example, when
*>  N = 6, KD = 2, and UPLO = 'U':
*>
*>  On entry:                       On exit:
*>
*>      *    *   a13  a24  a35  a46      *    *   u13  u24  u35  u46
*>      *   a12  a23  a34  a45  a56      *   u12  u23  u34  u45  u56
*>     a11  a22  a33  a44  a55  a66     u11  u22  u33  u44  u55  u66
*>
*>  Similarly, if UPLO = 'L' the format of A is as follows:
*>
*>  On entry:                       On exit:
*>
*>     a11  a22  a33  a44  a55  a66     l11  l22  l33  l44  l55  l66
*>     a21  a32  a43  a54  a65   *      l21  l32  l43  l54  l65   *
*>     a31  a42  a53  a64   *    *      l31  l42  l53  l64   *    *
*>
*>  Array elements marked * are not used by the routine.
*> \endverbatim
*
*> \par Contributors:
*  ==================
*>
*>  Peter Mayes and Giuseppe Radicati, IBM ECSEC, Rome, March 23, 1989
*
*  =====================================================================
      SUBROUTINE zpbtrf( UPLO, N, KD, AB, LDAB, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, KD, LDAB, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         AB( LDAB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
      INTEGER            NBMAX, LDWORK
      parameter( nbmax = 32, ldwork = nbmax+1 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, I2, I3, IB, II, J, JJ, NB
*     ..
*     .. Local Arrays ..
      COMPLEX*16         WORK( LDWORK, NBMAX )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zgemm, zherk, zpbtf2, zpotf2, ztrsm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( ( .NOT.lsame( uplo, 'U' ) ) .AND.
     $    ( .NOT.lsame( uplo, 'L' ) ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( kd.LT.0 ) THEN
         info = -3
      ELSE IF( ldab.LT.kd+1 ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZPBTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment
*
      nb = ilaenv( 1, 'ZPBTRF', uplo, n, kd, -1, -1 )
*
*     The block size must not exceed the semi-bandwidth KD, and must not
*     exceed the limit set by the size of the local array WORK.
*
      nb = min( nb, nbmax )
*
      IF( nb.LE.1 .OR. nb.GT.kd ) THEN
*
*        Use unblocked code
*
         CALL zpbtf2( uplo, n, kd, ab, ldab, info )
      ELSE
*
*        Use blocked code
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Compute the Cholesky factorization of a Hermitian band
*           matrix, given the upper triangle of the matrix in band
*           storage.
*
*           Zero the upper triangle of the work array.
*
            DO 20 j = 1, nb
               DO 10 i = 1, j - 1
                  work( i, j ) = zero
   10          CONTINUE
   20       CONTINUE
*
*           Process the band matrix one diagonal block at a time.
*
            DO 70 i = 1, n, nb
               ib = min( nb, n-i+1 )
*
*              Factorize the diagonal block
*
               CALL zpotf2( uplo, ib, ab( kd+1, i ), ldab-1, ii )
               IF( ii.NE.0 ) THEN
                  info = i + ii - 1
                  GO TO 150
               END IF
               IF( i+ib.LE.n ) THEN
*
*                 Update the relevant part of the trailing submatrix.
*                 If A11 denotes the diagonal block which has just been
*                 factorized, then we need to update the remaining
*                 blocks in the diagram:
*
*                    A11   A12   A13
*                          A22   A23
*                                A33
*
*                 The numbers of rows and columns in the partitioning
*                 are IB, I2, I3 respectively. The blocks A12, A22 and
*                 A23 are empty if IB = KD. The upper triangle of A13
*                 lies outside the band.
*
                  i2 = min( kd-ib, n-i-ib+1 )
                  i3 = min( ib, n-i-kd+1 )
*
                  IF( i2.GT.0 ) THEN
*
*                    Update A12
*
                     CALL ztrsm( 'Left', 'Upper', 'Conjugate transpose',
     $                           'Non-unit', ib, i2, cone,
     $                           ab( kd+1, i ), ldab-1,
     $                           ab( kd+1-ib, i+ib ), ldab-1 )
*
*                    Update A22
*
                     CALL zherk( 'Upper', 'Conjugate transpose', i2, ib,
     $                           -one, ab( kd+1-ib, i+ib ), ldab-1, one,
     $                           ab( kd+1, i+ib ), ldab-1 )
                  END IF
*
                  IF( i3.GT.0 ) THEN
*
*                    Copy the lower triangle of A13 into the work array.
*
                     DO 40 jj = 1, i3
                        DO 30 ii = jj, ib
                           work( ii, jj ) = ab( ii-jj+1, jj+i+kd-1 )
   30                   CONTINUE
   40                CONTINUE
*
*                    Update A13 (in the work array).
*
                     CALL ztrsm( 'Left', 'Upper', 'Conjugate transpose',
     $                           'Non-unit', ib, i3, cone,
     $                           ab( kd+1, i ), ldab-1, work, ldwork )
*
*                    Update A23
*
                     IF( i2.GT.0 )
     $                  CALL zgemm( 'Conjugate transpose',
     $                              'No transpose', i2, i3, ib, -cone,
     $                              ab( kd+1-ib, i+ib ), ldab-1, work,
     $                              ldwork, cone, ab( 1+ib, i+kd ),
     $                              ldab-1 )
*
*                    Update A33
*
                     CALL zherk( 'Upper', 'Conjugate transpose', i3, ib,
     $                           -one, work, ldwork, one,
     $                           ab( kd+1, i+kd ), ldab-1 )
*
*                    Copy the lower triangle of A13 back into place.
*
                     DO 60 jj = 1, i3
                        DO 50 ii = jj, ib
                           ab( ii-jj+1, jj+i+kd-1 ) = work( ii, jj )
   50                   CONTINUE
   60                CONTINUE
                  END IF
               END IF
   70       CONTINUE
         ELSE
*
*           Compute the Cholesky factorization of a Hermitian band
*           matrix, given the lower triangle of the matrix in band
*           storage.
*
*           Zero the lower triangle of the work array.
*
            DO 90 j = 1, nb
               DO 80 i = j + 1, nb
                  work( i, j ) = zero
   80          CONTINUE
   90       CONTINUE
*
*           Process the band matrix one diagonal block at a time.
*
            DO 140 i = 1, n, nb
               ib = min( nb, n-i+1 )
*
*              Factorize the diagonal block
*
               CALL zpotf2( uplo, ib, ab( 1, i ), ldab-1, ii )
               IF( ii.NE.0 ) THEN
                  info = i + ii - 1
                  GO TO 150
               END IF
               IF( i+ib.LE.n ) THEN
*
*                 Update the relevant part of the trailing submatrix.
*                 If A11 denotes the diagonal block which has just been
*                 factorized, then we need to update the remaining
*                 blocks in the diagram:
*
*                    A11
*                    A21   A22
*                    A31   A32   A33
*
*                 The numbers of rows and columns in the partitioning
*                 are IB, I2, I3 respectively. The blocks A21, A22 and
*                 A32 are empty if IB = KD. The lower triangle of A31
*                 lies outside the band.
*
                  i2 = min( kd-ib, n-i-ib+1 )
                  i3 = min( ib, n-i-kd+1 )
*
                  IF( i2.GT.0 ) THEN
*
*                    Update A21
*
                     CALL ztrsm( 'Right', 'Lower',
     $                           'Conjugate transpose', 'Non-unit', i2,
     $                           ib, cone, ab( 1, i ), ldab-1,
     $                           ab( 1+ib, i ), ldab-1 )
*
*                    Update A22
*
                     CALL zherk( 'Lower', 'No transpose', i2, ib, -one,
     $                           ab( 1+ib, i ), ldab-1, one,
     $                           ab( 1, i+ib ), ldab-1 )
                  END IF
*
                  IF( i3.GT.0 ) THEN
*
*                    Copy the upper triangle of A31 into the work array.
*
                     DO 110 jj = 1, ib
                        DO 100 ii = 1, min( jj, i3 )
                           work( ii, jj ) = ab( kd+1-jj+ii, jj+i-1 )
  100                   CONTINUE
  110                CONTINUE
*
*                    Update A31 (in the work array).
*
                     CALL ztrsm( 'Right', 'Lower',
     $                           'Conjugate transpose', 'Non-unit', i3,
     $                           ib, cone, ab( 1, i ), ldab-1, work,
     $                           ldwork )
*
*                    Update A32
*
                     IF( i2.GT.0 )
     $                  CALL zgemm( 'No transpose',
     $                              'Conjugate transpose', i3, i2, ib,
     $                              -cone, work, ldwork, ab( 1+ib, i ),
     $                              ldab-1, cone, ab( 1+kd-ib, i+ib ),
     $                              ldab-1 )
*
*                    Update A33
*
                     CALL zherk( 'Lower', 'No transpose', i3, ib, -one,
     $                           work, ldwork, one, ab( 1, i+kd ),
     $                           ldab-1 )
*
*                    Copy the upper triangle of A31 back into place.
*
                     DO 130 jj = 1, ib
                        DO 120 ii = 1, min( jj, i3 )
                           ab( kd+1-jj+ii, jj+i-1 ) = work( ii, jj )
  120                   CONTINUE
  130                CONTINUE
                  END IF
               END IF
  140       CONTINUE
         END IF
      END IF
      RETURN
*
  150 CONTINUE
      RETURN
*
*     End of ZPBTRF
*
      END